A way to "introduce" new characters

[CharacterGreen]

I just recently started using Ren'Py so please understand if I don't understand the basics of it.

In my visual novel, new characters will be showing up as the story goes along. In real life, you wouldn't know a new person's name by looking at them and that's the idea I want to implement into my VN. I'm looking for a way to have something like "???" for the character's name until they introduce themselves to the main character, and then from that point on, instead of "???" it would be the character's name.

It would be very helpful to doing my visual novel considering it's a crucial part of the game.

[Imperf3kt]

Are you using side images? Because if you aren't, I'd suggest just naming a character "???" and using them before introducing the actual name of the character

Code: Select all

define bob = Character('Bob')
define bill = Character('Bill')
define nobody = Character('???')
define sarah = Character('Sarah')

label start:
    bob "Hi, I'm Bob."
    nobody "Hello Bob."
    bob "Uh, who are you?"
    bill "Oh, sorry Bob. My name is Bill."
    nobody "Oh, so you're Bill. Nice to meet you!"
    bob "Bill, I'd like tou to meet Sarah."
    sarah "Its a pleasure to meet you, Bill."
    return
    

[gas]

A longer but flexible alternative to that.

Code: Select all

default girlname="???"

define girl = Character("[girlname]")

label start:
    girl "Hey you wait!"
    $ girlname="Blonde Girl"
    "A blonde girl approach"
    girl "Aren't you GAS, the uncanny and awesome genius?"
    girl "I'm Lilith, nice to meet you."
    $ girlname="Lilith"
    girl "... I'm there to bring you to the worst part of love."
 

[CharacterGreen]

Oh thank you so much, this really helped me so much and it works exactly as I wanted it to!

[XxrenxX]

I know this resolved but adding for anyone that may plan for voices to be integrated.

Code: Select all

define dad = Character('Dad', color="#ac0000", voice_tag="Dad") 
define da2 = Character('???', color="#ac0000", voice_tag="Dad") 

In my own, and I completely realize this can be tedious, I have defined 2 separate tags for a character. One for when the character ins't known, and another for when they are.

Ignore the rest if you don't plan to use voice tags

Code: Select all

screen preferences:
    tag menu
    modal True
        
    imagemap:
        ground "GUI/Pref/Options_Ground.png"
        hover "GUI/Pref/Options_Hover.png"
        selected_idle "GUI/Pref/Options_SIdle.png"
        
            #Voice Toggle
        hotspot (489,322,31,25) action ToggleVoiceMute("Dad")

Code: Select all

voice "Dad" "03_0460.ogg" 
dad "\"my voice can now be muted separately from other characters.\""