Making text appear when you hover over a choice?

[Rudje]

Is there a way to make a "pop up" (probably not the term I want, but...) appear when you hover over a choice? I'm making a fan VN for FFV and that's the method i want to implement for warnings/information about a given story since the "paths" are all just distinct stories with fairly different tones. Worse comes to worst I can implement the warnings as a a choice within a choice, but I'd rather try something more elegant and less intrusive.

I searched, but couldn't find anything (probably because I'm not using the right terminology because it seems like something that would have come up before).

As an example of what I'm trying to do, at the start of the game you get a bunch of choices, and hovering over those choices displays text in a box that says stuff along the lines of "Characters: Bartz, Galuf, Lenna, Faris, Mood: Saturday morning cartoon, Content warnings: character death, meatfort". Something like that. I can make a mock-up if needed.

[xavimat]

Go to screens.rpy and change the screen choice with this one:

Code: Select all

screen choice(items):
    style_prefix "choice"

    vbox:
        for i in items:
            if '|' in i.caption:
                $ i1 = i.caption.split('|')[0]
                $ i2 = i.caption.split('|')[1]
                textbutton i1 action i.action tooltip i2
            else:
                textbutton i.caption action i.action

    $ tooltip = GetTooltip()

    if tooltip:
        frame:
            align (.9,.8)
            text tooltip

You can use it adding the | character as separator in menu choices.

Code: Select all

label start:
    menu:
        "Path 1|Characters: Lenna, Faris\nMood: Saturday morning cartoon\nContent warnings: character death":
            pass
        "Path 2|Characters: Bartz, Galuf\nMood: Sunday evening cartoon\nContent warnings: sugarcandy":
            pass
        "A path without tooltip":
            pass[/choice]

[Rudje]

Thank you! Do I replace everything under choice or just the first section? e: Nevermind, figured it out. Thank you again, this helps a ton!

[xavimat]

Thank you! Do I replace everything under choice or just the first section?

Only the screen choice itself (the original is pretty short actually, six lines, one of which is empty).
The lines after the screen are definitions and styles. They affect the screen but are not not part of the screen itself.