Uncle Mugen's Cookbook Clock in RenPy 7.0.0??

[venerable_bead]

I'm new to RenPy and Python programming. To kick things off I found Uncle Mugen's Cookbook Clock cookbook ATL example via this excellent article:

Tutorial & Code: Analog/Digital Clock as User Defined Display

The article says it was updated in June 2016 and that Uncle Mugen's clock works in RenPy 6.18. It is July 2018 now and I'm using RenPy 7.0.0.

I tried the example clock code; it initially displayed the clock but as the minutes increased the hands stay still.

I managed to get it working by tweaking it a little:

Code: Select all

init:
    $ minutes = 540

image hourhand = "hourhand.png" # Short Clockhand
image minutehand = "minutehand.png" # Long Clockhand
image clockface = "clockface.png" # Clockface

transform rotatelong(mins):
    xanchor 0.5
    yanchor 0.5
    xalign 0.5
    yalign 0.5
    rotate (mins*6)

transform rotateshort(mins):
    xanchor 0.5
    yanchor 0.5
    xalign 0.5
    yalign 0.5
    rotate (mins*0.5)

transform alpha_dissolve:
    alpha 0.0
    linear 0.5 alpha 1.0
    on hide:
        linear 0.5 alpha 0
    # This is to fade in the clock.

screen clock:
    text "minutes: [minutes]"
    frame at alpha_dissolve:
        xmaximum 250 # X size of clock graphic
        ymaximum 250 # Y size of clock graphic
        xalign 0.99 # X placement on screen
        yalign 0.02 # Y placement on screen
        add "clockface"
        add "minutehand" at rotatelong(minutes)
        add "hourhand" at rotateshort(minutes)
# The game starts here.

label start:
    "What time is it?"
    "Let's look at the clock."
    show screen clock
    "Ah!... Nice clock!"
    "It is already 9:00AM."
    "He is very late."
    "But he is my friend so I will wait."
    $ minutes += 2
    "Two minutes has passed."
    $ minutes += 2
    "Four minutes has passed."
    $ minutes += 2
    "Six minutes has passed."
    "HE IS LATE! I KILL HIM!"
    hide screen clock

I know there have been many changes between 6.18 and 7.0.0 but I'm interested to know why the original code no longer works.

Is this change in behaviour documented somewhere? (or is it a bug?)

I'm trying to understand the rules of when variable changes would cause a screen to be updated.

Many thanks

Please excuse my RenPy or Forum etiquette ignorance.

[xavimat]

Screens are predicted many times, so updating a variable outside a screen usually is shown immediately in it.

I don't know if has anything to do: try adding parenthesis in the screen definition:

Code: Select all

screen clock():

[DragonKnight]

But, wheres the clock??

[venerable_bead]

In case anybody was wondering. I recovered Mugen's images from the internet archive:

https://web.archive.org/web/20170115220 ... /Clock.png
https://web.archive.org/web/20170115220 ... lock_1.png
https://web.archive.org/web/20170115220 ... lock_2.png

[venerable_bead]

Adding the parenthesis to the original code didn't seem to help.

Screens are predicted many times, so updating a variable outside a screen usually is shown immediately in it.

I don't know if has anything to do: try adding parenthesis in the screen definition:

Code: Select all

screen clock():

[trooper6]

Just a note, My Clock Code (the more complicated version) works in 7.0--my project uses my Clock and if works fine.

Anyhow, using the clock files posted above, I made a project with the working Mugen Code, all updated to 7.0 conventions:

Code: Select all

image hourhand = "images/Clock_1.png" # Short Clockhand
image minutehand = "images/Clock.png" # Long Clockhand
image clockface = "images/Clock_2.png" # Clockface

default minutes = 540

transform rotatelong(mins):
    xanchor 0.5
    yanchor 0.5
    xalign 0.5
    yalign 0.5
    rotate (mins*6)

transform rotateshort(mins):
    xanchor 0.5
    yanchor 0.5
    xalign 0.5
    yalign 0.5
    rotate (mins*0.5)

transform alpha_dissolve:
    alpha 0.0
    linear 0.5 alpha 1.0
    on hide:
        linear 0.5 alpha 0
    # This is to fade in the clock.

screen clock():
    vbox:
        text "minutes: [minutes]"
        frame at alpha_dissolve:
            xmaximum 250 # X size of clock graphic
            ymaximum 250 # Y size of clock graphic
            xalign 0.99 # X placement on screen
            yalign 0.02 # Y placement on screen
            add "clockface"
            add "minutehand" at rotatelong(minutes)
            add "hourhand" at rotateshort(minutes)
# The game starts here.

label start:
    "What time is it?"
    "Let's look at the clock."
    show screen clock
    "Ah!... Nice clock!"
    "It is already 9:00AM."
    "He is very late."
    "But he is my friend so I will wait."
    $ minutes += 2
    "Two minutes has passed."
    $ minutes += 2
    "Four minutes has passed."
    $ minutes += 2
    "Six minutes has passed."
    "HE IS LATE! I KILL HIM!"
    hide screen clock

    return

MugenClockUpdated.zip

(749.65 KiB) Downloaded 19 times

[xavimat]

Another note.
I've tried the old code (posted by OP), and it works Ok too.
It's not good practice now to define variables on init, but it works.

OP's problem is elsewhere.

[trooper6]

I think it is either a) not having click images at all or b) having clock images but improperly defining them.