(SOLVED)How to jump to a new label when all menu options have been selected?

[YumaDazai]

So I'm coding a visual novel, and at one part you have 3 options that disappear after you select them. How can I jump to the next part of the story after all of the options have been selected?

Code: Select all

label 3d:
  
    $ white = 1
    $ red = 1
    $ yellow = 1

Code: Select all

menu flowers:
    "White" if white:
        $ white = 0
         jump white
    "Red"  if red:
        $ red = 0
         jump red
    "Yellow" if yellow:
        $ yellow = 0
         jump yellow
         
         #what do I do after this?

Or would this work better?

Code: Select all

 #before start label
default white = False
default red = False
default yellow = False

Code: Select all

menu flowers:
    "White" if not white:
         jump white
    "Red"  if not red:
         jump red
    "Yellow" if not yellow:
         jump yellow

Code: Select all

#at the end of each label jump
if white and red and yellow:
   jump cs
else:
    jump menu flowers

[dGameBoy101b]

All you need to do is add an if test after the menu to test for all selected choices. Also using the call statement allows you to easily get back to the menu once the player has finished a particular choice's route.

Code: Select all

label flowers:
     menu flowers:
        "White" if white:
            $ white = 0
             call white
         "Red"  if red:
            $ red = 0
             call red
         "Yellow" if yellow:
             $ yellow = 0
              call yellow  
          if white == 0 and red == 0 and yellow == 0:
              jump continue
           else:
               jump flowers
label continue:              

[YumaDazai]

Thank you!

[philat]

You can also use this undocumented but useful behavior: viewtopic.php?f=8&t=42976#p447121

Code: Select all

label 3d:
    $ flowers_set = []
    menu flowers:
        set flowers_set
        "White":
            call white
        "Red":
            call red
        "Yellow":
            call yellow  
    if len(flowers_set) < 3:
        jump flowers
    # implicitly, if the length of flowers_set is 3 or greater, it will fall through to the label cs
    # if the script is organized differently, you can also add an explicit else jump cs

label cs:
    "stuff"

[trooper6]

I would do this like so:

Code: Select all

default flowers_set = []

label start:
    "Your game starts."
    
    menu flowers:
        set flowers_set
        "Choose a flower."
        "White":
             jump white
        "Red":
             jump red
        "Yellow":
             jump yellow
             
    "Your game continues here."
    "Your game is over."
    return
    
label white:
    "You look at the white flowers."
    jump flowers
    
label red:
    "You look at the red flowers."
    jump flowers
    
label yellow:
    "You look at the yellow flowers."
    jump flowers 

Very importantly, I wouldn't call the white/red/yellow...I'd jump, so that you can jump to the menu rather than return (which would put you at the end of the menu, not repeat it).

[dGameBoy101b]

I wouldn't call the white/red/yellow...I'd jump, so that you can jump to the menu rather than return

By calling the flower text you can easily access the same text again from somewhere else without worrying about where it is beinging called from as it will just return to where it was called like so.

Code: Select all

default flowers = []
menu:
    set flowers
    "Oh, some flowers!"
    "white":
    	call white_flowers
    "red":
    	call red_flowers
    "yellow":
    	call yellow_flowers
jump continue
label white_flowers:
    "Some lovely white flowers."
    return
label red_flowers:
    "some lovely red flowers."
    return
label yellow_flowers:
    "Some lovely yellow flowers."
    return
label continue:
    "I continue walking."
    menu:
        "How lucky am I! Some more flowers!"
        "red":
            call red_flowers
        "white":
            call white_flowers
    jump continue1

Also that set behaviour is so cool! I've been doing that manually before now.

[trooper6]

That the call returns where you came from is exactly why you shouldn't use it in this instance.

You had to create a secondary menu that repeats the first menu with one of the options taken out. My version just uses one menu. It is much more efficient. The way you set up your code, the set function is never used because you never return back to the top of the original menu.

[dGameBoy101b]

That the call returns where you came from is exactly why you shouldn't use it in this instance.

You had to create a secondary menu that repeats the first menu with one of the options taken out. My version just uses one menu. It is much more efficient. The way you set up your code, the set function is never used because you never return back to the top of the original menu.

My previous code was not demonstrating how to repeat a menu only how the sub labels of the first menu can be recalled from another part of the code if, for instance, the main character encounters a similar bed of flowers.