How to make introduction text?

[henvu50]

When you click start new game, I want the following to happen:

1. black screen.
2. text fades in centered

"Welcome to the game."

3. wait for player to left click
4. previous text stays on screen
5. fade in new text slightly below previous text

"Welcome to the game."
"There are many interesting things about this game."

6. wait for player to left click
7. fade in new text below previous text

"Welcome to the game."
"There are many interesting things about this game."
"This is more text fading in, below the other text."

Here is my existing code:

Code: Select all

	pause 1.0

	show text "Welcome." with dissolve

	# wait for player to left click
	pause 999.0

	show text "This text erases this previous text, that's not what I want. I want this text to display below the Welcome text." with dissolve

	# wait for player to left click
	pause 999.0
    
	show text "This text erases this previous text, that's not what I want. I want this text to display below the Welcome text." with dissolve

	# wait for player to left click
	pause 999.0

The problem with the above code is if I left click once, it skips all the text.

[henvu50]

If you want to pause and wait until the player left clicks, just use pause without a duration

Code: Select all

show text "Welcome."
# wait for user to left click
pause

# *user left clicks*, but show text won't be skipped because we're using pause without a duration specified

show text "This text won't be skipped."
# wait for user to left click
pause

Now I just need to figure out how to get the text to stay on the screen instead of replacing the previous text.

[Andredron]

show text "text1 {w} \nText2" with dissolve

Text tag in launcher renpy, in tytorial

[henvu50]

I made each line of text a screen, so then I just show the screens.

Code: Select all

screen cust_intro_text1:

    # yalight .4
    text "Welcome." xalign 0.5 yalign 0.4

screen cust_intro_text2:

    # yalight .5
    text "Hello, more information here." xalign 0.5 yalign 0.5 

Code: Select all

    show screen cust_intro_text1
    pause

    show screen cust_intro_text2
    pause

    hide screen cust_intro_text1
    hide screen cust_intro_text2

The only problem now is I can't apply dissolve or fade to the show screen transitions. *sigh*

[henvu50]

show text "text1 {w} \nText2" with dissolve

Text tag in launcher renpy, in tytorial

That shows text1 & Text2 at the same time.

I want to show Text1 with a fade then wait for user left click. Then after they left click, it fades in Text 2 below Text1.

i've figured out most of it already, except I don't know how to get the show screen to apply a transition like dissolve or fade.

[henvu50]

Okay here is the complete code on how to show introduction text in a clean manner with fading, enjoy.

Code: Select all

screen cust_intro_text1:
    text "Welcome." xalign 0.5 yalign 0.4 at fade_screen

screen cust_intro_text2:
    text "Hello, more information here." xalign 0.5 yalign 0.5 at fade_screen

transform fade_screen:
    on show:
        alpha 0.0
        linear 1.0 alpha 1.0
    on hide:
        linear 0.5 alpha 0.0

label start:

    show screen cust_intro_text1
    pause

    show screen cust_intro_text2
    pause

    hide screen cust_intro_text1
    hide screen cust_intro_text2

[IrinaLazareva]

another example..

Code: Select all

image textv1 = ParameterizedText(xalign=0.5, yalign=0.4)
image textv2 = ParameterizedText(xalign=0.5, yalign=0.5)
image textv3 = ParameterizedText(xalign=0.5, yalign=0.6)
    
label start:
    scene black 
    pause 1.0
    show textv1 "Welcome." with dissolve
    pause
    show textv2 "There are many interesting things about this game." with dissolve
    pause
    show textv3 "This is more text fading in, below the other text." with dissolve 
    pause
    scene black with dissolve

https://renpy.org/doc/html/text.html#ParameterizedText

[henvu50]

another example..

Code: Select all

image textv1 = ParameterizedText(xalign=0.5, yalign=0.4)
image textv2 = ParameterizedText(xalign=0.5, yalign=0.5)
image textv3 = ParameterizedText(xalign=0.5, yalign=0.6)
    
label start:
    scene black 
    pause 1.0
    show textv1 "Welcome." with dissolve
    pause
    show textv2 "There are many interesting things about this game." with dissolve
    pause
    show textv3 "This is more text fading in, below the other text." with dissolve 
    pause
    scene black with dissolve

https://renpy.org/doc/html/text.html#ParameterizedText

This is a lot more efficient, thank you.