[solved] Simple real time digital clock like that?

[Nanahs]

I've seen some really good clock tutorials here.
But I wanted one that would look like this:



A real time one (import real time). That would only show the hour and the minute.
It doesn't need to be inside of a box or anything. Just show it like that (picture above).
Does anyone know how I can do that?

Thanks xx

[DannX]

This is the method I've been using to get the time and it seems to work well, there are probably other (maybe better) ways, but here it is:

Code: Select all

init python:

    import time

    def get_current_time():
        return time.strftime('%H:%M')
        
screen my_clock():

    $ hour = get_current_time()

    text hour xalign .99

    timer .01 repeat True action SetScreenVariable('hour', get_current_time())

[IrinaLazareva]

little update:

Code: Select all

init python:
    import time
    def mytime(st, at):
        return Text(time.strftime('%H:%M'), size=30), 0
image mytimes = DynamicDisplayable(mytime)

then just...

Code: Select all

label start:
    show mytimes at topright

or with screen...

Code: Select all

screen jclock():
    add 'mytimes' at topright
label start:
    show screen jclock

[DannX]

Code: Select all

init python:
    import time
    def mytime(st, at):
        return Text(time.strftime('%H:%M'), size=30), 0
image mytimes = DynamicDisplayable(mytime)

Ah, I knew there had to be a less redundant way, this is so much better!
Thank you IrinaLazareva! I'll update mine too!

[Nanahs]

Thank you guys! I'll give it a try