If statements in different labels

[bahiahanna]

Uh, so hey. I have been having issues with this certain topic. Every time I do something like this it would have give me a exception error. I dunno what is wrong with it, or is there a another way to do this. To cut it short, I was planning to do a VN that has 3 stories in it, for example, A, B and C. If you choose A, you'll get some info about something. Once done, you'll be left with B and C. If you choose one of them, you have to bring your previous info to that story. Usually, it would work. But, let's say you want to choose B first, right? Label B requires the if info == True statement which you would get in Label A, but since you didn't choose story A at all, you didn't have the info true in the first place, so that's why there is a else option. But this is where the game gets an error, saying that name "info" is not defined, even though it is defined in Label A. And this is where I need help. Here is an example:

Code: Select all

label start:    
    $ story1 = False
    $ story2 = False
    
label menu1:
    
menu:
    "Story 1" if story1 == False:
        $ story1 = True
        jump story1
    "Story 2" if story2 == False:
        $ story2 = True
        jump story2
label story1:
    $knowledge = False
    "Hi, did you know what happened last night"
menu:
    "Yes":
        $knowledge = True
        "The thunderstorm stormed, right?"
        "Yes"
        jump menu1 
    "No":
        "It's best that you don't know"
        jump menu1
label story2:
    "What happened last night, I kinda have forgotten"
menu:
    "I don't know, sorry":
        "It's OK"
        return
    "A thunderstorm stormed harshly yesterday" if knowledge == True:
        "Ah, yes. I have finally remembered, thank you so much!"
        return

Would be gladly appreciated if anybody could help. Even if you couldn't help, thanks for taking your time to read my non-worthy issues

[trooper6]

All variables must first be initialized outside of any block using default (if the variables will change their value) or define (if they will never change their values).

So...

Code: Select all

default story1 = False
default story2 = False
default knowledge = False

label start:        
    menu menu1:
        "Story 1" if story1 == False:
            $ story1 = True
            jump story1
        "Story 2" if story2 == False:
            $ story2 = True
            jump story2
            
label story1:
    menu:
        "Hi, did you know what happened last night?"
        "Yes":
            $knowledge = True
            "The thunderstorm stormed, right?"
            "Yes"
            jump menu1 
        "No":
            "It's best that you don't know"
            jump menu1
            
label story2:
    menu:
        "What happened last night, I kinda have forgotten."
        "I don't know, sorry":
            "It's OK"
            return
        "A thunderstorm stormed harshly yesterday" if knowledge == True:
            "Ah, yes. I have finally remembered, thank you so much!"
            return

Also I'll note in your post you say you have a problem with "info" not being defined when you defined it in story1...but you don't define info in story1, you define knowledge in story1.

[bahiahanna]

Actually, the "info" not being defined was the VN i was working on. This was just an example. Wow, Thank you so much! It actually worked. Really appreciated!