"Day name" stuck in first value

[Mai Goe]

I hope the topic subject is not too confusing.
So I tried a code from another thread, but it's posted in 2012 so not sure if I should post my question there. It's basically converts day number to day name.

Code: Select all

label start:
    label days:
        scene bg park
        show eileen happy at center
        with dissolve
        e "We will now execute the days system."
        $ day = 0
        $ day_name_values = ["Sunday", "Monday", "Tuesday", "Wednesday", "Thrusday", "Friday", "Saturday"]
        $ day_name = day_name_values[(day%7)]
        label dayprogress:
        menu:
            "sleep":
                $ day += 1
                e "Today is Day [day], [day_name]."
                jump dayprogress

When I try running the game, the number of day as in [day] proceeds as I click the "sleep" choice. However the [day_name] stuck in "Sunday". I wonder what did I do wrong, perhaps it's a problem with the syntax?
Please help me, thanks!

[Per K Grok]

[
When I try running the game, the number of day as in [day] proceeds as I click the "sleep" choice. However the [day_name] stuck in "Sunday". I wonder what did I do wrong, perhaps it's a problem with the syntax?
Please help me, thanks!

day_name is not updated because it is under 'label day'.
to get it to update you need to have it under 'label dayprogress'

Also be careful on how you indent the code.

Code: Select all

label start:

label days:
    scene bg park
    show eileen happy at center
    with dissolve
    e "We will now execute the days system."
    $ day = 0
    $ day_name_values = ["Sunday", "Monday", "Tuesday", "Wednesday", "Thrusday", "Friday", "Saturday"]

label dayprogress:
    menu:
        "sleep":
            $ day += 1
            $ day_name = day_name_values[(day%7)]
            e "Today is Day [day], [day_name]."
            jump dayprogress

[trooper6]

None of that is going to work because variables don't automatically update. Also you need to declare your variables using default (if the variable will change) or define (if it won't), outside any block. Here is a way to get what you want using a class.

Code: Select all

init python:
    class Calendar(object):
        def __init__(self):
            self.number = 0
            self.names = ["Sunday", "Monday", "Tuesday", "Wednesday", "Thrusday", "Friday", "Saturday"]

        @property
        def name(self):
            return self.names[self.number%7]

default day = Calendar()

# The game starts here.

label start:

    scene black
    "We will now test the say system. Please take note of indentation."
    menu dayprogress:
        "sleep":
            $day.number += 1
            "Today is Day [day.number], [day.name]"
            jump dayprogress
        "end":
            pass

    "Game over."

    return

[Mai Goe]

None of that is going to work because variables don't automatically update. Also you need to declare your variables using default (if the variable will change) or define (if it won't), outside any block. Here is a way to get what you want using a class.

It works, thank you very much!