In game menu with single use choices

[APD13]

First of all, I want to say hello as this is my first post on this forum and it is cool to see that there are people with whom I can share the same passion and that is a game dev. I am relatively new to Ren'py so I have a question regarding the in-game menu.
I would like to create an in-game menu from which the user will have to choose from, let's say three options. The tricky part is that if the user will choose option menu A after the scenes are finished the user should be redirected to the scene with the menu and there should be only two remaining option for selection. After another option is selected and the scenes are finished the user will be redirected again to the menu with the remaining option for selection. How do I translate this into a script?

Thank you

[CSV]

If I understood your issue correctly, then you can use something like this.

Code: Select all

# The game starts here.
label start:   
    $ OptionARead = False
    $ OptionBRead = False
    $ OptionCRead = False

    N "This is where the story starts."
    
label firstchoice:  
    N "There's a choice menu coming up!"

    menu:
        "Option A." if OptionARead == False:
            $ OptionARead = True
            jump sceneA
            
        "Option B." if OptionBRead == False:
            $ OptionBRead = True
            jump sceneB           
            
        "Option C." if OptionCRead == False:
            $ OptionCRead = True
            jump sceneC
            
label sceneA:
    N "You chose option A!"
    N "Let's try to move on."
    if OptionARead == True and OptionBRead == True and OptionCRead == True:
        jump anotherscene
    else:
        jump firstchoice

label sceneB:
    N "You chose option B!"
    N "Let's try to move on."
    if OptionARead == True and OptionBRead == True and OptionCRead == True:
        jump anotherscene
    else:
        jump firstchoice
 
label sceneC:
    N "You chose option C!"
    N "Let's try to move on."
    if OptionARead == True and OptionBRead == True and OptionCRead == True:
        jump anotherscene
    else:
        jump firstchoice

label anotherscene:
    "And now the story can move on."

I tried to name everything so you can easily change it to suit your needs. Also, please note that I am not a programmer, so there might be better ways to achieve this effect!

[trooper6]

Here is a better way to achieve what you want.

Code: Select all

default flowers_set = [] #variables should be declared outside of any block using default if the variable will change, define if it won't

label start:
    "Your game starts."

    menu flowers:
        set flowers_set
        "Choose a flower."
        "White":
             jump white
        "Red":
             jump red
        "Yellow":
             jump yellow

    "Your game continues here."
    "Your game is over."
    return

label white:
    "You look at the white flowers."
    jump flowers

label red:
    "You look at the red flowers."
    jump flowers

label yellow:
    "You look at the yellow flowers."
    jump flowers

[Imperf3kt]

Here is a better way to achieve what you want.

Code: Select all

default flowers_set = [] #variables should be declared outside of any block using default if the variable will change, define if it won't

label start:
    "Your game starts."

    menu flowers:
        set flowers_set
        "Choose a flower."
        "White":
             jump white
        "Red":
             jump red
        "Yellow":
             jump yellow

    "Your game continues here."
    "Your game is over."
    return

label white:
    "You look at the white flowers."
    jump flowers

label red:
    "You look at the red flowers."
    jump flowers

label yellow:
    "You look at the yellow flowers."
    jump flowers

I don't understand this, how does this work?
It looks like a list, but you don't add or remove anything?

[philat]

It's undocumented behavior but there are a bunch of forum posts about it and (as of right now) it works. *shrug* The logical assumption is that the menu statement is "translated" into renpy.menu or whatever, and somewhere in the process there is a sort of set-checking behavior embedded.

[APD13]

Thank you guys, I am going to try it now

[APD13]

I am here with feedback. It worked and thank you all for the support. GG