Button actions performed on screen call without clicking them?

[chadochocinco]

Hey all,

I have a problem where I'm calling a screen to display variables and buttons, and long story short: I click a button to move to a new location, and my time advances 120 minutes (the combined total of all my time updates for my buttons). It would appear that, when I jump to new location and make my screen calls, it displays my time properly, but on the call, the action of my text buttons all gets performed.

How do I correct this/prevent this from happening? Why would the actions from my buttons be getting done without clicking them?

I expect to click the text button, have timeofday increase by that much time via the clock(amount) function. I'd also love the screens to refresh on clicking that, but that'll be my follow-up (couldn't figure out how to get renpy.restart_interaction() to work).

Code: Select all

    
    	init 2 python:

###########################
# Routines                #
###########################
    	def clock(amount):
        global timeofday
        global day
        global daydisplay
        global dayname
        timeofday = timeofday + int(amount)
        if timeofday > 1440:
            timeofday = timeofday - 1440
            day = day + 1
            daydisplay = dayname [((day-1)%7)]
            return
        elif timeofday < 0:
            timeofday = 0
            return
        else:
            timeofday = timeofday
            return

screen headsupdisplay:
    zorder -1
    $clockhour = int(timeofday/60)
    $clockmin = timeofday - (clockhour * 60)
    $money_k = int(money)

    add "genuitop"
    vbox xpos 1700 ypos 10:
        hbox xpos 40 ypos 10:
            if clockhour < 10:
                text "{=clock_text}0[clockhour]"
            else:
                text "{=clock_text}[clockhour]"
            if clockmin < 10:
                text "{=clock_text}:0[clockmin]"
            else:
                text "{=clock_text}:[clockmin]"
        hbox xpos 40 spacing 5:
            vbox:
                textbutton "{=clock_button_text}5" action clock(5)
            vbox:
                textbutton "{=clock_button_text}10" action clock(10)
            vbox:
                textbutton "{=clock_button_text}15" action clock(15)
            vbox:
                textbutton "{=clock_button_text}30" action clock(30)
            vbox:
                textbutton "{=clock_button_text}60" action clock(60)

    vbox xalign .5 ypos 10:
        text "{=stats_text}[daydisplay], Day [day]"

    vbox xalign .5 ypos 50:
        text "{=stats_text}[location]"

[philat]

viewtopic.php?t=26101#p319388

[trooper6]

That post about currying is a bit out of date. The OP should just use the Function action, which does take variables.
https://www.renpy.org/doc/html/screen_a ... l#Function

On the other hand...there is a lot I'd do differently with that code in general.

[chadochocinco]

That post about currying is a bit out of date. The OP should just use the Function action, which does take variables.
https://www.renpy.org/doc/html/screen_a ... l#Function

On the other hand...there is a lot I'd do differently with that code in general.

I'll gladly accept any advice - trust me, I'm stumbling through all of this and welcome guidance.

[trooper6]

What is {=clock_button_text} and {=stats_text}? Also you have money_k as a variable, but I don't see where it is used in that screen.

[philat]

It's somewhat out of date but the principle concept (that you should not use functions in screens unless curried or wrapped in an Action of some sort) still stands, which was the main point. Also, currying still works perfectly fine.

[chadochocinco]

What is {=clock_button_text} and {=stats_text}? Also you have money_k as a variable, but I don't see where it is used in that screen.

Styles
style clock_text:
color "#F0F0F0"
font "gui/font/consolas.ttf"
size 40

style clock_button_text:
color "#FF9900"
font "gui/font/consolas.ttf"
size 20

money_k was a leftover for something I was going to have displayed in the hud, but am redesigning as well.

[chadochocinco]

And thank you guys for your answers so far. Wasn't familiar with currying, but it makes sense how I should approach this now

[trooper6]

Here is the code as I'd do it. This is tested and it works...you'd probably just want to change some of the styling.

Code: Select all

init python:
    class Calendar(object):
        def __init__(self):
            self.timeofday = 0
            self.day = 1
            self.daydisplay = "Sunday"
            self.dayname = ["Sunday", "Monday", "Tuesday", "Wednesaday", "Thursday", "Friday", "Saturday"]
        def advance(self, amount):
            self.timeofday += amount
            if self.timeofday > 1440:
                self.timeofday -= 1440
                self.day += 1
                self.daydisplay = self.dayname[((self.day-1)%7)]
            elif self.timeofday < 0:
                self.timeofday = 0
            return
        def timestring(self):
            ch = self.timeofday/60
            cm = self.timeofday - (ch*60)
            return "{:02d}:{:02d}".format(ch, cm)

default cal = Calendar()

screen headsupdisplay():
    zorder -1
    frame:
        vbox:
            text "{}".format(cal.timestring())
            hbox:
                textbutton "5" action Function(cal.advance, 5)
                textbutton "10" action Function(cal.advance, 10)
                textbutton "15" action Function(cal.advance, 15)
                textbutton "30" action Function(cal.advance, 30)
                textbutton "60" action Function(cal.advance, 60)

            text "[cal.daydisplay], Day [cal.day]"