How to make a textbutton action make appear a text somewhere?

[jacob_ax]

Hi guys!
I'm trying to make a quest diary, but the problem I'm having is that I'd like to show some text (taken from a dictionary) inside a frame when I click on a textbutton. Here is an image that shows what I'd like to do:

Capture.PNG

(8.75 KiB) Not downloaded yet

And here is the code:

Code: Select all

screen quest_screen:
    frame:
        xpos 150
        ypos 100
        hbox:
            frame:
                vbox:
                    textbutton "Quest 1" action [take the quest 1 text from a dictionary and show inside the frame below]
                    textbutton "Quest 2" action [take the quest 2 text from a dictionary and show inside the frame below]
            frame:
                text"Suppose clicked on Quest 1, here should appear a description of the quest."

What is the action I should use? Is there a different approach to solve this problem? I suspect that it's much more complicated than I think
Thanks

[trooper6]

Make a new project with this code to test it out.

Code: Select all

default quest_dict = {"q1":"This is the description of Quest 1",
"q2":"This is the description of Quest 2"}

screen quest_screen():
    default quest_text = None
    frame:
        xpos 150
        ypos 100
        hbox:
            frame:
                vbox:
                    textbutton "Quest 1" action SetScreenVariable("quest_text", quest_dict["q1"])
                    textbutton "Quest 2" action SetScreenVariable("quest_text", quest_dict["q2"])
            frame:
                text"[quest_text]"

label start:

    "Test Start"
    show screen quest_screen()
    "End Test"
    "Game Over"
    return

[jacob_ax]

Make a new project with this code to test it out.

Code: Select all

default quest_dict = {"q1":"This is the description of Quest 1",
"q2":"This is the description of Quest 2"}

screen quest_screen():
    default quest_text = None
    frame:
        xpos 150
        ypos 100
        hbox:
            frame:
                vbox:
                    textbutton "Quest 1" action SetScreenVariable("quest_text", quest_dict["q1"])
                    textbutton "Quest 2" action SetScreenVariable("quest_text", quest_dict["q2"])
            frame:
                text"[quest_text]"

label start:

    "Test Start"
    show screen quest_screen()
    "End Test"
    "Game Over"
    return

Thank you very very much trooper6, it works wonderfully