Main Menu Help!

[Akutasan]

Hello.
I wanted to have a Logo appear in the main menu before the game starts.
I'm a beginner and don't know how to do...
This is what I've got but I don't even know what I'm writing and Google isn't really helping..

Code: Select all

   image main_menu:
        "gui/logo/Example.png"
[...]

show main_menu:
    add "main_menu"
    xpos=0.25
    ypos=0.25
    
label start:

And if someone could tell me, what

Code: Select all

add "main_menu"

means, it'd be really greatful
(Sorry for my bad english...)

[isobellesophia]

A splashscreen would be useful.

viewtopic.php?t=46121

[Per K Grok]

Hello.
I wanted to have a Logo appear in the main menu before the game starts.
I'm a beginner and don't know how to do...
This is what I've got but I don't even know what I'm writing and Google isn't really helping..

Code: Select all

   image main_menu:
        "gui/logo/Example.png"
[...]

show main_menu:
    add "main_menu"
    xpos=0.25
    ypos=0.25
    
label start:

And if someone could tell me, what

Code: Select all

add "main_menu"

means, it'd be really greatful
(Sorry for my bad english...)

Try this

Code: Select all

add "gui/logo/Example.png" xpos 200 ypos 200

Put in screens.rpy under "screen main_menu():".

xpos and ypos is the position in pixels counted from the screens top left image to the top left corner of the image.
You can not have fractions of a pixel, so xpos = 0.25 makes no sense.

[mitoky]

Hello!
You would need a splashscreen for this. I did a tutorial on this before, so i am copy pasting the template here for you (each step is explained, feel free to ask if you have questions!)

Code: Select all

#####################################################################################
## Transforms 
#####################################################################################

#Transformation for Logo    
transform transform_logo:
    on show:
        alpha 0 xalign 0.5 yalign 0.5
        linear 2.0 alpha 1
    on hide:
        linear 2.0 alpha 0

#Transformation for background
transform transform_white:
    on show:
        alpha 0 
        linear 2.0 alpha 1
    on hide:
        linear 2.0 alpha 0

#####################################################################################
## Images
#####################################################################################

#Your Logo
image logo = "gui/logo/Example.png"
#A Black BG
image black = "#000000"
#A White BG
image white = "#ffffff"    

#####################################################################################
## Splashscreen
#####################################################################################

label splashscreen:
    scene black #We start with a black scene
    $ renpy.pause(1, hard=True) #Pauses the black screen for a second. This command pauses renpy, hence makes it unable to click
    
    show white at transform_white #next we swho our white screen with our made transformation
    $ renpy.pause(2, hard=True) #For this its important to know the transformation time. Since the transformation is "happening" at the same time, the pause needs to be at least as long as the transformation. Otherwise it gets cut off.
    
    show logo at transform_logo #Next, we are showing our logo with our logo transformation.
    $ renpy.pause(6, hard=True) #Our logo takes 2 second to appear, however, we want it to stay on the screen for a while, hence we are using 6 instead of 2 seconds, so it stays for 4 seconds.
    
    hide logo #Next we are hiding our logo
    $ renpy.pause(2, hard=True) #Since the transformation is 2 seconds long, the pause here is 2 seconds long.
    
    hide white #Next we are hiding our background.
    $ renpy.pause(3, hard=True) # Our hiding transformation for the white bg takes 2 seconds, but since we want the screen to stay black for a second, like at the beginning, we use 3 instead.
    
    return