Character say a following when player inputs characters names.

[isobellesophia]

Hi,

As i said in the title above how can i do that?

I have my input code.

Code: Select all

  f "Oh! i forgot your name, what was it again?"
    
    screen input(prompt):
        window at truecenter:   
            xmaximum 500
            background Image("gui/nameinput.png")  
            vbox:
                xalign 0.5
                yalign 0.5
                text prompt style "input_prompt"
                input id "input"
            
    python:
      name = renpy.input("What is your name?")

      name = name.strip() or "Human"
      
    show f happy 1 with dissolve
    f "Oh yeah! it's [name], right?"

For example, the player types "Fina", and when after he inputs that, the real "Fina" character will say a thing, and let the player to choose again, vice versa for all character names.

Code: Select all

f "Whoops! That is my name, how about something else?

Thanks.

[strayerror]

This should do what you're looking for. It uses a sub-label (notice the label name starts with a dot) to jump back to the prompt each time the user enters the disallowed name.

Code: Select all

label getting_to_know_you:
    f "Oh! i forgot your name, what was it again?"
    label .prompt_for_name:
    $ name = renpy.input("What is your name?").strip() or "Human"
    if name == f.name: # could hard code the name if you prefer using: name == "Fina"
        f "Whoops! That is my name, how about something else?"
        jump .prompt_for_name
    show f happy 1 with dissolve
    f "Oh yeah! it's [name], right?"
    return

[lacticacid]

Code: Select all

jump choosename
label choosename:
    python:
      name = renpy.input("What is your name?")

      name = name.strip() or "Human"

    if name=="Fina":
        f "Whoops! That is my name, how about something else?"
        jump choosename
    else:
        f "Oh yeah! it's [name], right?"

Something like this. Putting this under a label will allow the game to return there after the wrong name choice and, well, "if-else" statements are self-explanatory.
; )

[isobellesophia]

Thank you guys! Its working like a charm!

[Imperf3kt]

This could be extended to include a python list, and check if multiple names are used.