Script running in background

[Exiscoming]

Not sure if this is possible, but I don't think this is too hard of a question.
How do I make a script that continues playing / repeating while the rest of the game continues as normal?
I'd basically like to add something as simple as this:

Code: Select all

default guardDirection = 1			# 1 is looking left, 2 is looking right

layeredimage guard:
	if guardDirection == 1:
		"guard.png"
	if guardDirection == 2:
		"guard.png"
		xzoom -1				# Flip image

label guardScript:
	show guard
	pause 2.0
	$ guardDirection = 2
	pause 2.0
	$ guardDirection = 1
	jump guardScript

Obviously, the above code creates an infinite loop. But it it possible to do something like this?

[strayerror]

You could use a transform to do this:

Code: Select all

layeredimage guard:
    "guard.png"

transform guard_anim:
    pause 2.0
    xzoom -1
    pause 2.0
    xzoom 1
    repeat

label guardScript:
    show guard at guard_anim
    'end'
    return

[Exiscoming]

Hi there stray, thanks for your suggestion!
So unfortunately that won't work exactly as I hoped. It's important that I can update variables.
That way I can check with an if statement to see if the guard is currently looking at the player.
For example:

Code: Select all

if guardDirection == 1:
	"You managed to sneak by."
else:
	"You've been caught!"

You can't put variable changes inside of a transform, right?

[strayerror]

Aha, in that case, I'm not sure if it's the best way, but you could use a custom transform to publish the guard's direction to a variable:

Code: Select all

layeredimage guard:
    'guard.png'

default guard_direction = 1

init python:
    def guard_sweep(trans, st, at):
        global guard_direction # publish direction globally
        guard_direction = trans.xzoom = -guard_direction # reverse direction
        return 2 # seconds until next flip

label guardScript:
    show guard:
        function guard_sweep
    'We need to sneak past, just say when!'
    if guard_direction == 1:
        'You managed to sneak by.'
    else:
        "You've been caught!"
    'end'
    return