Playing a sound when opening a screen - sound keeps looping!

[thirstyoctopus]

Hi everyone

This is getting a bit annoying now, but what I'm trying to do is create a screen in my game that's like a notebook that the player can open to check some progress notes. I would like a sound to play when this happens, so I sourced a clip of a page being turned which sounds quite fitting.

However, it seems to play on every mouse click / button press as you are progressing through the dialogue, as well as the screen too.

Here's my code:

To set up the toggle key:

Code: Select all

screen notepad_toggle:
    if renpy.get_screen("crush_notes"):
        key "n" action Hide("crush_notes")
    else:
        key "n" action Show("crush_notes")

The screen that opens:

Code: Select all

screen crush_notes():

    $ renpy.play("fx/open_notebook.ogg")

    key "dismiss" action Hide("crush_notes")

    style_prefix "notebook"

    vbox:
        spacing 15

        frame:
            xalign 0.5
            ypos 0
            xpadding 50
            ypadding 70
            xfill True
            yfill True
            background "notepad bg"

            vbox:
                box_wrap True
                xsize 340
                xpos 480
                ypos 35

                text notes

I'm assuming that what's happening is that the play function is triggering because the screen is always 'there' even though it's not showing - but I don't know how to only get it to play once when the screen is opened, and then only again once the screen is re-opened.

Is there a way of doing this?

[Matalla]

I usually use this for these kind of things

Code: Select all

timer 0.01 action Play("sound", "sounds/page turn.mp3")

This is actually a line from the project I'm working on, not a "whatever" example. And I'm doing it with a notebook like yours and similar sound effect (stop copying me, damn it!!).

On a (slightly) more serious note, also check that the channel you're playing the sound on, isn't on a loop. To my shame, it has happened to me.

Also, using "on show" could work too (and probably is the proper way to do it), but I'm using this clumsy method since I started with renpy and I had absolutely no freaking clue about anything. Now that I have ascended to the "barely no clue" category, I keep using it because I'm a sentimental guy who gets attached to silly things.

[thirstyoctopus]

Hey, thanks for the info.

Doing a bit more digging I found using the 'on' statement worked:

Code: Select all

on "show" action Play("sound", "fx/open_notebook.ogg")
on "hide" action Play("sound", "fx/open_notebook.ogg")

This code is placed directly at the end of the screen block, so it only activates on show and hide of that particular screen.