[solved] Screen with choice of gender

[Leviy]

Hello.
I want to do choice of gender of character at the beginning of the game. I decided to realize that through screen in "screens.rpy". But how do I assign the result of choice to a specific variable in "script.rpy"?

screens.rpy.
screen choise_gender:
vbox align (0.5,0.5):
imagemap:
ground "scene/choise_gender.png"
hover "scene/choise_genderhover.png"
alpha True
hotspot (837, 501, 150, 77) action Return("Female")
hotspot (1032, 501, 151, 81) action Return("Male")

I tried to do that this way:

label start:
call screen choise_gender
if renpy.call_screen("Female"):
$ gender = f

But it didn't work. Error screen Female not known.

[IrinaLazareva]

call screen choise_gender
if renpy.call_screen("Female"):
$ gender = f

Code: Select all

label start:
    call screen choise_gender
    if _return == "Female":
        $ gender = 'f'

https://www.renpy.org/doc/html/screen_a ... tml#Return

P.S. if desired, you can directly change the value of the variable with the appropriate action().

[namastaii]

You're trying to call a screen named 'female' and 'male' instead of assigning a variable.

Before the start label, include this:

Code: Select all

default gender = ""

If you'd like the default to be a specific gender, then put default gender = "female" etc

In your screen where your hotspots are, you'd do

Code: Select all

hotspot (837, 501, 150, 77) action SetVariable("gender", "female")
hotspot (1032, 501, 151, 81) action SetVariable("gender", "male")

If these hotspots also move to the next scene as soon as you click the gender, then you can have the hotspot return two actions

Code: Select all

hotspot (837, 501, 150, 77) action [SetVariable("gender", "female"), Jump("next_scene")]
hotspot (1032, 501, 151, 81) action [SetVariable("gender", "male"), Jump("next_scene")]

Code: Select all

label next_scene:
    if gender == "female":
        "You have chosen to be a girl"
    else:
        "You have chosen to be a boy"