Optimizing the code

[Grifin]

So i have code for ypos change in the choicemenu which I need once

Code: Select all

screen choice(items):
    if name == "True":
        style_prefix "choicen"
    else:
        style_prefix "choice"

    vbox:

        for i in items:
            textbutton i.caption action i.action

define config.narrator_menu = True

style choicen_vbox is vbox
style choicen_button is button
style choicen_button_text is button_text
style choicen_vbox:
    xalign 0.5
    ypos 700
    yanchor 0.5

    spacing gui.choice_spacing
style choicen_vbox:
    xalign 0.5
    ypos 700
    yanchor 0.5

    spacing gui.choice_spacing

style choicen_button is default:
    properties gui.button_properties("choice_button")

style choicen_button_text is default:
    properties gui.button_text_properties("choice_button")
    size 30

style choice_vbox is vbox
style choice_button is button
style choice_button_text is button_text
style choice_vbox:
    xalign 0.5
    ypos 700
    yanchor 0.5

    spacing gui.choice_spacing
style choice_vbox:
    xalign 0.5
    ypos 500
    yanchor 0.5

    spacing gui.choice_spacing

And then in the script, I do

Code: Select all

$ name = "True"

When I want ypos to change

But I know this is quite dumb way to do
How I can optimize this?

[Angelo Seraphim]

Firstly;

Code: Select all

$ name = "True"

Is this suppose to be a boolean type variable? If so, then it should just be True without quotation marks.

What's the difference between "choice" and "choicen" in your styles? Is that just for changing the vbox?
You probably don't need to do:

Code: Select all

if name == "True":
    style_prefix "choicen"
else:
    style_prefix "choice"

...but instead maybe do:

Code: Select all

screen choice(items):
	
    style_prefix "choice"

    vbox:
        if name:
            ypos 500
        else:
	    ypos 700
	for i in items:
	    textbutton i.caption action i.action

[Remix]

You could use the _mode parameter of the menu system...

Code: Select all

screen choice(items):
    style_prefix "choice"

    vbox:
        ypos (700 if renpy.get_mode() == "lower_menu" else 500)
        for i in items:
            textbutton i.caption action i.action

Then, just add it as wanted

Code: Select all

label start:

    "lower menu"
    menu (_mode="lower_menu"):
        "A":
            pass
        "B":
            pass
            
    "normal menu"
    menu:
        "A":
            pass
        "B":
            pass
    "..."

[Grifin]

Thank you, I'll you use mode parameter, it's more convenient