How to 'stop' game when I show player interactivemap?

[MuteSummer]

Hello. So, we got this: player read some text, and then in corner of screen appear button "Map" . Untill player click this button, game mustnt end, and no other text must appear (at least I try make it like this). Whats best way to solve this problem?

[Per K Grok]

Hello. So, we got this: player read some text, and then in corner of screen appear button "Map" . Untill player click this button, game mustnt end, and no other text must appear (at least I try make it like this). Whats best way to solve this problem?

I would use

$ renpy.pause(hard=True)

though that is somewhat frowned upon.
You would then need something that take the player beyond that stop point. You could have a jump to label in the screen action that gets the game running again when the player done what it where supposed to do.

[Imperf3kt]

maybe call in new context?
https://www.renpy.org/doc/html/label.ht ... ew_context

[gas]

I dunno if you want for that "text" to stay put, but more probably what you want for is to CALL that screen.

call screen mybutton

The execution stop until something do a Return action.
Your button can Show another screen the same and execution doesn't proceed as long as you don't give a Return action somewhere (more probably selecting the location in that map).

[strayerror]

You can use screenlang's modal True to achieve this effect.

If we use the screen to intercept interactions similar to the suggestion by gas, but use show screen rather than call screen we're able to display it overlaid on dialogue instead of outright replacing it. The caveat to this approach is that because we've forgone the secret sauce provided by call screen, we must hide the button screen ourselves when we're finished with it. In this example we use the button action to simply Return which acts as a normal player click/interaction that advances the game, and explicitly hide the screen in the next line of the script/dialogue that we're progressing through.

There are also some nice side-benefits to this approach: By leveraging show screen in conjunction with Return rather than Jump or Call actions, the rollback system simply sees the advancement as a normal interaction giving us safe rollback-compatible progression with working rollback and roll-forward despite having forced the player to take an action on a screen. It's also skip-proof, providing an experience very similar in style to Ren'Py's out of the box menu system. Finally, using a screen allows access to the usual accessibility features, allowing additional information to be given to visually-impaired users about the non-standard progression method if desired, and by default allowing the use of the keyboard to proceed (via the arrow keys to locate the button and enter to "click") if they're unable to visually locate the button.

Hope this A) is what you wanted, and B) helped! XD

Code: Select all

label start:
    scene black
    "At first, everything was dark."
    "There was nothing for it."
    show screen the_button()
    "If I was to make it out alive, I'd have to click the map."
    hide screen the_button
    jump map

label map:
    scene
    "It turned out the map was a lie."
    "Unfinished, with nowhere to go. What a silly demo."
    pause
    return

screen the_button():
    modal True

    textbutton 'Map':
        action Return()
        align (.95, .95)
        hover_background '#666'
        idle_background '#333'
        padding (10, 10)

[gas]

...
[/code]

You don't need a Return() that way, you can simply Hide() as action. That doesn't require the need to directly hide the screen.
Anyway, I suppose that button is there to actually show somethingm, probably that map screen... Who knows XD.

[MuteSummer]

Hello. So, we got this: player read some text, and then in corner of screen appear button "Map" . Untill player click this button, game mustnt end, and no other text must appear (at least I try make it like this). Whats best way to solve this problem?

I would use

$ renpy.pause(hard=True)

though that is somewhat frowned upon.
You would then need something that take the player beyond that stop point. You could have a jump to label in the screen action that gets the game running again when the player done what it where supposed to do.

Thanks! That definetly what I needed!:3

[strayerror]

You don't need a Return() that way, you can simply Hide() as action. That doesn't require the need to directly hide the screen.
Anyway, I suppose that button is there to actually show somethingm, probably that map screen... Who knows XD.

Unfortunately using Hide (and removing the hide screen line comes with numerous drawbacks:
- Clicking it won't appear to do anything, the button vanishes but nothing progresses.
- It's not rollback safe - try rolling back and forward over the click, when rolling forward the button will stay visible, and because the screen is modal it'll block non-roll-forward progression until clicked again.
- It requires including the screen name in the definition of the screen, which can hamper development when needing to rename a screen or copy paste a snippet for reuse, so it's a nice QoL boost if we can possibly avoid it.

The idea with using show screen is a little cheaty - we as developers know that clicking the button is mandatory to progress, so there's no need for a branching dialogue or code path, we just temporarily change the method of progression. The jump map in the example is intended to represent the jump to the map proper, what the map dialogue does (call a map screen, display an image), doesn't matter for the purposes of this mechanic.

Hope that provides some insight as to why sometimes Hide isn't an ideal solution. :)

[jeffster]

Another way to stop the dialogue from progression is using a character with advance = False:

Code: Select all

define stopper = Character(kind = adv, advance = False)

label start:
    "The usual narration - you can click through."
    stopper "But it stops here."
    "Can't get here unless you make some buttons for this."