[Solved] ATL inside Hide()

[Potato0095]

I'm trying to do a phone animation, click on a imagebutton, show screen, click in another imagebutton, hide screen. The problem is: I can't find a way to use action Hide("phone") with ATL. Should I continue with this and try to do the animations, or should I simply re-do from scrath without using a screen?

Code: Select all

screen phone:
    tag menu
    modal True
    style_group "phone"
    image phone_wallpaper:
        anchor 0, 0 pos 950, 5
        at phone_in
    image "images/Phone/Phone.png":
        anchor 0, 0 pos 950, 5
        at phone_in
    imagebutton idle "images/Phone/Button_exit.png" action Hide("phone") pos 1000, 525 focus_mask True:
        at button_in

[gas]

Try to use an "on hide" clause in the transform itself.
This is an example.

Code: Select all

transform notify_appear:
    on show:
        alpha 0
        linear .25 alpha 1.0
    on hide:
        linear .5 alpha 0.0

[Potato0095]

Try to use an "on hide" clause in the transform itself.
This is an example.

Code: Select all

transform notify_appear:
    on show:
        alpha 0
        linear .25 alpha 1.0
    on hide:
        linear .5 alpha 0.0

Heh, it worked with a few adjustments. It simply hid the images at first, not the screen itself, which is what I need (I don't know if that's intentional from Ren'Py). Adding another action ( Return() ) to the image button fixed this other issue. Thanks for the help.

Code: Select all

screen phone:
    tag menu
    modal True
    style_group "phone"
    image phone_wallpaper:
        anchor 0, 0 pos 950, 5
        at phone_atl
    image "images/Phone/Phone.png":
        anchor 0, 0 pos 950, 5
        at phone_atl
    imagebutton idle "images/Phone/Button_exit.png" action[ Hide("phone"), Return() ] pos 1000, 525 focus_mask True:
        at button_atl
        
transform phone_atl:
    on show:
        xpos 1300
        linear .25 xpos 950
    on hide:
        xpos 950
        linear .25 xpos 1300
        
transform button_atl:
    on show:
        xpos 1350
        linear .25 xpos 1000
    on hide:
        xpos 1000
        linear .25 xpos 1350