How to add +1 to a variable every second

[renardjap]

Hello guys !

I want to increase a resources variable every second. For exemple, when the player do an activity like mining iron, the iron variable increase every second +1
And I want to display the increasement on a screen. I know I need to do some loops... but I don't know how...

I search some tuto or advises on the forum, I found something with ui.timer but it's out of date (the post was written in 2008). I tried something in python

Code: Select all

python:
        iron = 0
        while True:
            iron +1
            time.sleep(1.0)

But my computer crashed...

I don't understand how work time and how can I use the function ? Can you help me ?

[IrinaLazareva]

Code: Select all

default iron = 0
screen resources():
    text "Iron: [iron]" at topleft
    timer 1.0 repeat True action SetVariable('iron', iron+1)
 
label start:
    '?'
    show screen resources
    '!'

The algorithm can be improved as you wish

https://renpy.org/doc/html/screens.html#timer
https://renpy.org/doc/html/screen_actio ... etVariable
https://renpy.org/doc/html/screens.html ... statements

4example:

Code: Select all

default gold = 0
default silver = 0
default vita = 1000

screen resources():
    vbox at topleft:
        text "Silver: [silver]"
        text "Gold: [gold]"
        text "Vita: [vita]"
    if vita>0:
        timer 1.0 repeat True action SetVariable('gold', gold+1)
        timer 3.7 repeat True action SetVariable('silver', silver+1)
        timer 10.0 repeat True action SetVariable('vita', vita-1)

[Alex]

Just a minor adding...

Code: Select all

default iron = 0

screen counter_scr():
    on "show" action Function(renpy.retain_after_load) # <---

    timer 1.0 action SetVariable("iron", iron + 1) repeat True
    text "iron: [iron]" align (0.05, 0.05)

label start:
    
    show screen counter_scr
    "?!"

https://www.renpy.org/doc/html/save_loa ... after-load

[renardjap]

It was finally so easy... when we know the solution... Thank you very much !

I have one more little problem: when I use the History and go back, the variable come back to zero... Is it possible to keep the score even we go back in the history ?

[rayminator]

you can try using these they might help

load and save

Code: Select all

renpy.retain_after_load()

Fixing Rollback
https://www.renpy.org/doc/html/save_loa ... g-rollback

Styling Fixed Rollback
https://www.renpy.org/doc/html/save_loa ... d-rollback