How to make defaultdict work with rollback [SOLVED]

[GigaChonker9000]

Here's a short game script that shows my problem:

Code: Select all

init python:
    from collections import defaultdict

default test_dict = defaultdict(int)

label start:
    "Test A"
    $ test_dict["key"] += 1
    $ num = test_dict["key"]
    "Current value: [num]"
    "Test B"

Between the lines "Test A" and "Test B", I want to increment the value of "key" by 1. However, when I rollback from "Test B" to "Test A", instead of reverting the value back to 0, it increments it again -- now the game is at "Test A" but the value of "key" is 2. You can do this repeatedly to make the value as large as you want.

This issue doesn't happen if I use a regular dictionary (replacing defaultdict(int) with {"key" : 0}); the current value stays at 1, as it should.

I'm not an expert with programming, but I assume it has to do with the fact that the value of the key isn't explicitly defined at the point we're trying to rollback to, it just uses the default value of 0. Is there any good way to work around this? If necessary I can switch to a regular dictionary and set all of the keys and values explicitly at the beginning, but a defaultdict would be a lot cleaner if possible.

[hell_oh_world]

Here's a short game script that shows my problem:

Code: Select all

init python:
    from collections import defaultdict

default test_dict = defaultdict(int)

label start:
    "Test A"
    $ test_dict["key"] += 1
    $ num = test_dict["key"]
    "Current value: [num]"
    "Test B"

Between the lines "Test A" and "Test B", I want to increment the value of "key" by 1. However, when I rollback from "Test B" to "Test A", instead of reverting the value back to 0, it increments it again -- now the game is at "Test A" but the value of "key" is 2. You can do this repeatedly to make the value as large as you want.

This issue doesn't happen if I use a regular dictionary (replacing defaultdict(int) with {"key" : 0}); the current value stays at 1, as it should.

I'm not an expert with programming, but I assume it has to do with the fact that the value of the key isn't explicitly defined at the point we're trying to rollback to, it just uses the default value of 0. Is there any good way to work around this? If necessary I can switch to a regular dictionary and set all of the keys and values explicitly at the beginning, but a defaultdict would be a lot cleaner if possible.

Renpy dicts are a custom class called RevertableDict. I guess you could just inherit in that class.

Code: Select all

init python:
    from collections import defaultdict
    
    class defdict(defaultdict, renpy.python.RevertableDict):
        pass
        
default test_dict = defdict(int)

label start:
    "Test A"
    $ test_dict["key"] += 1
    $ num = test_dict["key"]
    "Current value: [num]"
    "Test B"

[GigaChonker9000]

That works, thanks!

[henvu50]

I tried to do this with OrderedDict, but it doesn't work with rollback, but the method suggested above does indeed work with defaultdict.

Anyone know if it's possible to get OrderedDict to work with Rollback/RevertableDict? If not, it's not a big deal.