Click to continue icon

[Maou Zenigame]

Is there a way to include a click to continue icon that will appear in all game text without having to enable it in every single character definition?

[Imperf3kt]

Use a CTC screen
https://www.renpy.org/doc/html/screen_s ... o-continue

[Maou Zenigame]

Alright, I popped this in and it didn't actually do anything.

Code: Select all

screen ctc():

    zorder 100
    add "gui/Textbox/emblem_ctc.png" at kaiten

transform kaiten:
    xanchor 0.5 yanchor 0.5
    subpixel True
    rotate 0
    linear 3.0 rotate 360
    repeat

[Imperf3kt]

Are you using ADV or NVL mode?

[Maou Zenigame]

ADV mode.

[Maou Zenigame]

Upon second look, it's showing up on the upper left corner of the screen.
I know how to move it with x/y coordinates, but how would I get it to show up at the end of any given line of text in the textbox?

[Imperf3kt]

In that case, use an image tag at the end of each line {image='my image.png'}
But you'd have to do it for every line manually.

You could probably add it via character callbacks, but I have no experience with that.

[Milkymalk]

You can add a what_suffix for every character to append the image tag to every line a character speaks. You still need to do it for every character, but only once where you define them.

[MaydohMaydoh]

Taking a look at some stuff, it seems you can use https://www.renpy.org/doc/html/config.h ... s_callback to add a ctc to every say statement.

Code: Select all

image emblem:
    'gui/Textbox/emblem_ctc.png'
    align (.5, .5)
    subpixel True
    block:
        rotate 0
        linear 3.0 rotate 360
        repeat
        
init python:
    def say_arguments_callback(who, interact=True, ctc='emblem'):
        return (), { "interact" : interact, "ctc" : ctc, "ctc_position" : "nestled" }

    config.say_arguments_callback = say_arguments_callback

[Maou Zenigame]

Thanks, that works perfectly.

Is there any way to get the indicator to show up when the text is paused with the {w} tag as well?

[MaydohMaydoh]

Giving the image to ctc_pause should do the trick.

Code: Select all

return (), { "interact" : interact, "ctc" : ctc, "ctc_pause" : ctc, "ctc_position" : "nestled" }

[Maou Zenigame]

That did the trick.
Thank you so much, I've been trying to figure this out for weeks now to no avail.