[Solved]How do I show all the layers at once?

Message

JinzouTamashii · #1 Post by **JinzouTamashii** » Fri Oct 02, 2009 8:25 pm

I remember seeing it somewhere but forum search, Wiki, and demo game have all failed me ...

Alex · #2 Post by **Alex** » Fri Oct 02, 2009 8:50 pm

What does it mean "show all the layers at once"? What do you want to see on screen?

JinzouTamashii · #3 Post by **JinzouTamashii** » Fri Oct 02, 2009 10:48 pm

I want to show the background, the character, an object sprite, and another overlay (transparent PNG) all on the screen at the very same time without combining all the images together...

Aleema · #4 Post by **Aleema** » Sat Oct 03, 2009 1:27 am

You can show however many things you want with the "show" command.
In fact, they will keep showing until you tell them to "hide" (or call another image within the same subset).

Overlays, if configured right, will only show when you set their conditional to True.

JinzouTamashii · #5 Post by **JinzouTamashii** » Sat Oct 03, 2009 3:44 am

I'm not making myself clear somehow ... maybe there is a language barrier...

I want everything to appear all at once, with a dissolve. Multiple things. Not one at a time.

Melkoshi · #6 Post by **Melkoshi** » Sat Oct 03, 2009 4:00 am

Dont quote me on this. but I think it's

show ---
show---
show---
with ---effect here---

I'm asumeing your doing "show--- with -effect-"?

JinzouTamashii · #7 Post by **JinzouTamashii** » Sat Oct 03, 2009 4:50 am

Yes.

Thank you, I will try it and get back to you.

JinzouTamashii · #8 Post by **JinzouTamashii** » Wed Oct 07, 2009 8:33 am

I have thought a long time about this and found another way to put it.

I want to create a "stack" of images and show all of those layers at once with the show command with dissolve.

Jake · #9 Post by **Jake** » Wed Oct 07, 2009 8:48 am

JinzouTamashii wrote:I want to create a "stack" of images and show all of those layers at once with the show command with dissolve.

It's exactly as Melkoshi said. If I have five images defined for different characters, and I want to show them all appearing on screen in different positions at once, with a dissolve, all at the same time, I can do:

Code: Select all

  show albert at far_left
  show bernardette at left
  show charles at center
  show derek at right
  show eleanor at far_right
  with dissolve

and Ren'Py will dissolve all five characters into their respective positions simultaneously.

If I want them all to appear in the same spot, one on top of the other, I can do the same thing just with the same position for all characters.

If I want to fade Albert, Bernadette and Charles in at the same time, then far Derek and Eleanor in afterwards, I would instead do:

Code: Select all

  show albert at far_left
  show bernardette at left
  show charles at center
  with dissolve

  show derek at right
  show eleanor at far_right
  with dissolve

Basically, when Ren'Py gets told to show things, it keeps collecting them up and getting them ready to show until it hits a 'with' statement, and then it shows all of the things it has collected up, using the transition in that with statement, all at the same time. Then, once that's finished, it looks for the next thing to do - be it a line of dialogue, another show, whatever.

So, for example:

Code: Select all

  scene ballroom
  show albert at far_left
  show bernardette at left
  with fade
  show charles at center with dissolve
  show derek at right
  show eleanor at far_right
  with dissolve
  p "My, fancy meeting all you people here!"

This will fade to black, then fade back to a new scene in the ballroom, with Albert already at the far left and Bernadette at the left. Once the fade is complete, it will dissolve Charles in at the centre. It will wait for the dissolve to finish, then it will dissolve Derek and Eleanor in at the right at the same time. Once that dissolve is finished, it will finally display the line of dialogue.

Edit:

Alternatively, if by 'stack of images' you mean like dressing a paper doll to create your stacked image to display, then it's not a problem with show/with at all, you just need im.Composite. So:

Code: Select all

init:
  image bernadette dress glasses = im.Composite(
    None,
    (0,0), "bernadette_base.png",
    (0,0), "bernadette_dress.png",
    (0,0), "bernadette_glasses.png"
    )

Then use it like a regular image:

Code: Select all

  show bernadette dress glasses with dissolve

JinzouTamashii · #10 Post by **JinzouTamashii** » Wed Oct 07, 2009 8:56 am

You have clearly answered both parts of my question. I understood perfectly. Thank you very much.

Can I add your examples to the Wiki?

Jake · #11 Post by **Jake** » Wed Oct 07, 2009 9:28 am

JinzouTamashii wrote:You have clearly answered both parts of my question. I understood perfectly. Thank you very much.

You're welcome.

JinzouTamashii wrote:Can I add your examples to the Wiki?

Of course, if there's somewhere you think they'd be useful.

Lemma Soft Forums

[Solved]How do I show all the layers at once?

[Solved]How do I show all the layers at once?

Re: How do I show all the layers at once?

Re: How do I show all the layers at once?

Re: How do I show all the layers at once?

Re: How do I show all the layers at once?

Re: How do I show all the layers at once?

Re: How do I show all the layers at once?

Re: How do I show all the layers at once?

Re: How do I show all the layers at once?

Re: How do I show all the layers at once?

Re: How do I show all the layers at once?

Who is online