I can't load slots on one of my load screens

[Karrion]

I have to almost equal load state screens (I had to use two for layout reasons), and there are almost no changes on the two of them, however, on the normal one I can load with no problem, while on the clean one, I can't. The buttons don't respond, the text does not change to hover, etc, it's like the button is not there. Here is the code for both screens:

Code: Select all

screen save():

    tag menu

    use file_slots(_("Save"))


screen load():

    tag menu

    use file_slots(_("Load"))


screen file_slots(title):

    default page_name_value = FilePageNameInputValue(pattern=_("Page {}"), auto=_("Automatic saves"), quick=_("Quick saves"))

    add "images/template_menu_[title].jpg"

    fixed:

        ## This ensures the input will get the enter event before any of the
        ## buttons do.
        order_reverse True

        ## The page name, which can be edited by clicking on a button.

        ## The grid of file slots.
        grid gui.file_slot_cols gui.file_slot_rows:
            style_prefix "slot"

            xpos 484
            ypos 360

            xspacing 138
            yspacing 80

            for i in range(gui.file_slot_cols * gui.file_slot_rows):

                $ slot = i + 1

                button:
                    action FileAction(slot)

                    has vbox

                    add FileScreenshot(slot) xalign 0.5

                    text FileTime(slot, format=_("{#file_time}%a %m.%d.%Y"), empty=_(" ")):
                        xpos 162
                        ypos 30
                        size 72
                        layout "nobreak"
                        style "slot_time_text"

                    text FileSaveName(slot):
                        style "slot_name_text"

                    key "save_delete" action FileDelete(slot)

        ## Buttons to access other pages.
        hbox:
            xpos 471
            ypos 959
            imagebutton idle "button_back.png" action [ShowMenu("preferences"),Hide("file_slots", dissolve)]

        hbox:
            xpos 1034
            ypos 967
            spacing 7
            imagebutton idle "button_up.png" action FilePagePrevious()
            imagebutton idle "button_down.png" action FilePageNext()




style page_label is gui_label
style page_label_text is gui_label_text
style page_button is gui_button
style page_button_text is gui_button_text

style slot_button is gui_button
style slot_button_text is gui_button_text
style slot_time_text is slot_button_text
style slot_name_text is slot_button_text

style page_label:
    xpadding 75
    ypadding 5

style page_label_text:
    text_align 0.5
    layout "subtitle"
    hover_color gui.hover_color

style page_button:
    properties gui.button_properties("page_button")

style page_button_text:
    properties gui.button_text_properties("page_button")

style slot_button:
    properties gui.button_properties("slot_button")

style slot_button_text:
    properties gui.button_text_properties("slot_button")


##################################CLEAN LOAD###################################

screen loadclean():

    tag menu

    use file_slots_clean(_("Load"))


screen file_slots_clean(title):

    default page_name_value = FilePageNameInputValue(pattern=_("Page {}"), auto=_("Automatic saves"), quick=_("Quick saves"))

    add "images/template_[title]_clean.jpg"

    fixed:

        ## This ensures the input will get the enter event before any of the
        ## buttons do.
        order_reverse True

        ## The page name, which can be edited by clicking on a button.

        ## The grid of file slots.
        grid gui.file_slot_cols gui.file_slot_rows:
            style_prefix "slot"

            xpos 480
            ypos 293

            xspacing 138
            yspacing 80

            for i in range(gui.file_slot_cols * gui.file_slot_rows):

                $ slot = i + 1

                button:
                    action FileAction(slot)

                    has vbox

                    add FileScreenshot(slot) xalign 0.5

                    text FileTime(slot, format=_("{#file_time}%a %m.%d.%Y"), empty=_(" ")):
                        xpos 162
                        ypos 30
                        size 72
                        layout "nobreak"
                        color Color("#ffe0de")
                        style "slot_time_text"

                    text FileSaveName(slot):
                        style "slot_name_text"

                    key "save_delete" action FileDelete(slot)

        ## Buttons to access other pages.
        hbox:
            xpos 471
            ypos 959
            imagebutton idle "button_back.png" action Return()

        hbox:
            xpos 1034
            ypos 967
            spacing 7
            imagebutton idle "button_up.png" action FilePagePrevious()
            imagebutton idle "button_down.png" action FilePageNext()




style page_label is gui_label
style page_label_text is gui_label_text
style page_button is gui_button
style page_button_text is gui_button_text

style slot_button is gui_button
style slot_button_text is gui_button_text
style slot_time_text is slot_button_text
style slot_name_text is slot_button_text

style page_label:
    xpadding 75
    ypadding 5

style page_label_text:
    text_align 0.5
    layout "subtitle"
    hover_color gui.hover_color

style page_button:
    properties gui.button_properties("page_button")

style page_button_text:
    properties gui.button_text_properties("page_button")

style slot_button:
    properties gui.button_properties("slot_button")

style slot_button_text:
    properties gui.button_text_properties("slot_button")

The changes are mostly, the background image, the action of the "back_button", and the positioning of the grid. Any ideas why this is happening?

[MaydohMaydoh]

It's because of the screen name and the FileAction action.
FileAction checks if the screen name is "load" and returns the FileLoad action else it returns the FileSave action.

Code: Select all

if renpy.current_screen().screen_name[0] == "load":
    return FileLoad(name, page=page, **kwargs)
else:
    return FileSave(name, page=page, **kwargs)

So because your screen isn't called "load", it returns the FileSave action which causes the buttons to become insensitive when in the main menu, in a replay or if the page name is "auto". Either way, the loadclean would cause renpy to save instead of load even with the buttons enabled.
So basically you need to do it yourself instead of using the default FileAction by creating a new function.

Code: Select all

init python:
    def FileActionClean(name, page=None, **kwargs):
        if renpy.current_screen().screen_name[0] == "loadclean":
            return FileLoad(name, page=page, **kwargs)
        else:
            return FileSave(name, page=page, **kwargs)

Something like that.

[Karrion]

That worked perfectly! Thank you!