(Solved) Repeat only part of an ATL Transform?

[SypherZent]

How can I repeat only a portion of an ATL transform?

For example:

Code: Select all

image animated_image:
    "image_frame_1"
    pause 0.5
    "image_frame_2"
    pause 0.5
    "image_frame_3"
    pause 0.5

^ I want the above animated image to only repeat frames 2 and 3, not frame 1.

Do I need to use parallel? I feel like this should be easy, I just can't think of how to do it off the top of my head.

I'll have some more time to test it later, but figured I'd ask in case anyone can help, since I'm a bit loaded with work right now.

Thanks.

[Andredron]

Code: Select all

show logo base:
    xalign 0.0 yalign 0.0
    block:
        linear 1.0 xalign 1.0
        linear 1.0 xalign 0.0
        repeat
    time 11.5
    linear .5 xalign 1.0
    

label start:

Code: Select all

show magic:
        yalign .5 subpixel True
        parallel:
            xalign .5
            linear 3.0 xalign .75
            linear 6.0 xalign .25
            linear 3.0 xalign .5
            repeat
        parallel:
            alpha 1.0 zoom 1.0
            linear .75 alpha .5 zoom .9
            linear .75 alpha 1.0 zoom 1.0
            repeat
        parallel:
            rotate 0
            linear 5 rotate 360
            repeat
            

[Remix]

block

Code: Select all

image animated_image:
    "image_frame_1"
    pause 0.5
    block:
        "image_frame_2"
        pause 0.5
        "image_frame_3"
        pause 0.5
        repeat # just repeat the block

[SypherZent]

Hey, awesome, thank you! Really appreciate it.
The parallel method works nicely.

Any benefit to using block VS parallel?
Though, honestly, it runs smooth as a hot knife through butter with parallel.
I don't think optimization would even be visually noticeable.
May help for easier writing of the code to use block in the long run, though.

In any case, thank you for the help! Good to know that more than one way is possible. ^^