renpy.return from screen

[hapciupalit]

Hi there, I have a label and a screen with a button. When the button is pressed I call a function which checks for something and if that is True then it should return back in the label.

Code: Select all

label test:
	"something goes here"
	call screen test_screen()
	"I want to be back here"

screen test_screen():
	imagebutton:
		auto "path_to_url"
		action Function(testFunc)
		
init python:
	def testFunc():
		if something:
			# what should I do here to leave the screen and go back where I left.
			# I could do renpy.jump("test") but that will go back to "something goes here"
			# while in my case I would like to have something similar to action Return() which
			# would have return me to "I want to be back here"
		else :
			#something else

Thank you!

[_ticlock_]

Hi, hapciupalit,

Why not use another label or local label:

Code: Select all

label test:
    "something goes here"
    call screen test_screen()
label .something:
    "I want to be back here"

screen test_screen():
    imagebutton:
        idle "P1.jpg"
        action Function(testFunc)

init python:
    def testFunc():
        if something:
            renpy.jump("test.something")
        else:
            pass

[hell_oh_world]

If the function in the Function action returns value other than None, then it will end the interaction and return that value.

Code: Select all

init python:
  def myReturn(): return True # return any value other than None to end the interaction.
screen test():
  texbutton "Return" action Function(myReturn)

label start:
  call screen test
  "Continuation... Return value is [_return]"

[Remix]

Code: Select all

init python:
    def testFunc():
        if some_success_condition:
            return "success"
            ## returning a NOT None value is the same as Return() ... even return False or return 0 will be ok
        else:
            # returning None will keep the called screen there as though nothing had happened
            return None

The value returned incidentally can be later displayed or checked in the global _return variable's value

[hapciupalit]

Hi, hapciupalit,

Why not use another label or local label:

Code: Select all

label test:
    "something goes here"
    call screen test_screen()
label .something:
    "I want to be back here"

screen test_screen():
    imagebutton:
        idle "P1.jpg"
        action Function(testFunc)

init python:
    def testFunc():
        if something:
            renpy.jump("test.something")
        else:
            pass

Because this is a minigame that can start from different situations in the game.
I have a scene in which people come to my coffeeshop and ask for a coffee. Then I call my screen and then when I'm done preparing the coffee I should return back to the person giving, however the problem with more labels is the fact that I will then have to create a label for each situation and each customer. While if I can return where I left it solves plenty of writing.

[hapciupalit]

If the function in the Function action returns value other than None, then it will end the interaction and return that value.

Code: Select all

init python:
  def myReturn(): return True # return any value other than None to end the interaction.
screen test():
  texbutton "Return" action Function(myReturn)

label start:
  call screen test
  "Continuation... Return value is [_return]"

Cheers. This solved my problem.

By the way. Is there a way to know what my screen returned?
Something like this:

Code: Select all

label test:
	"Hi there"
	call screen test()
	"This is what my test returned : [???]"

Right now In my function I have something like this:

Code: Select all

def testFunc():
	if something:
		variable = True
		return True
	else:
		variable = False
		return False

So getting rid of the variable would be cool.

[RicharDann]

By the way. Is there a way to know what my screen returned?

hell_oh_world already demonstrated it, but there's a built-in special variable called _return that automatically stores whatever is returned from a screen or a return statement.

Code: Select all

label start:
  call screen test
  "Continuation... Return value is [_return]"

You can also use the python equivalent of call screen and store the result directly to a variable:

Code: Select all

default var = None
label start:
  $ var = renpy.call_screen('test')
  "Return value is [var]"

[gas]

Use just after the call line

Code: Select all

call screen test
$ stored = _return

and stored will be equal the returned value.

...as the guy writing the same time as me correctly said...

[hapciupalit]

By the way. Is there a way to know what my screen returned?

hell_oh_world already demonstrated it, but there's a built-in special variable called _return that automatically stores whatever is returned from a screen or a return statement.

Code: Select all

label start:
  call screen test
  "Continuation... Return value is [_return]"

You can also use the python equivalent of call screen and store the result directly to a variable:

Code: Select all

default var = None
label start:
  $ var = renpy.call_screen('test')
  "Return value is [var]"

Thank you very much!

[hapciupalit]

Use just after the call line

Code: Select all

call screen test
$ stored = _return

and stored will be equal the returned value.

...as the guy writing the same time as me correctly said...

Thanks. It works perfectly!