Unlockable second campaign.

[NadOtavlas]

So in my game I want there to be an unlockable second campaign after getting all of the endings in the game. This campaign is selectable as a on the main menu. I know if I want to program something like this I need to use persistent data but I don't actually know how it works. Can someone explain? Also can someone explain how to change the main menu to include this option?

[_ticlock_]

Hi, NadOtavlas,

You need persistent flags for each ending and optionally variable persistent.campaign2_unlocked.

Code: Select all

default persistent.ending_1 = False
default persistent.ending_2 = False
default persistent.campaign2_unlocked = False

Now when you reach an ending you change the corresponding variable to True and check if all endings are unlocked.

Code: Select all

label ending_1:
    ...
    $ persistent.ending_1 = True
    call check_campaign2_unlock
    return
    
label check_campaign2_unlock:
    if persistent.ending_1 and persistent.ending_2:
        $ persistent.campaign2_unlocked = True
    return

A simple example to add a button to the main menu:
In screens.rpy find screen navigation and add your button there:

Code: Select all

screen navigation():
    vbox:
        ...
        textbutton _("Preferences") action ShowMenu("preferences")
        textbutton _("Campaign 2"):
            if persistent.campaign2_unlocked:
                action Start('label_campaign2')

However, a better way is to use set to store the flags for endings:

Code: Select all

default persistent.endings = set()
label ending_1:
    ...
    $ persistent.endings.add("end_1")
    return

Then you can use len(persistent.endings) to see if all endings are reached: For 2 endings you will have:

Code: Select all

screen navigation():
    vbox:
        ...
        textbutton _("Preferences") action ShowMenu("preferences")
        textbutton _("Campaign 2"):
            if len(persistent.endings) == 2:
                action Start('label_campaign2')