Code is skipping to last label

[Vennnot]

Hey everyone, I'm quite new to renpy and I've been watching a couple of tutorials. I have this issue where my visual novel jumps to my last label and I don't know why. It should go to intro first and then go through the motions. As of right now it instantly skips to hallway 1 and I can't figure out why. Any help is appreciated:

Code: Select all

define main = Character("[name]", color="#ffffff") # The player, man #1

define emm = Character("Emma", color="#cc75ff") # Emma, girl #3

# Define images and resolutions

image hallway2 = "hallway2.png"
image hallway1 = "hallway1.png"

image test_happy = "hoshi_school_smile.png"
image test_embarrassed1 = "hoshi_school_embarrassed1.png"
image test_embarrassed2 = "hoshi_school_embarrassed2.png"
image test_upset = "hoshi_school_upset.png"




# The game starts here. Ask for players name, if no name is given, return Robbie

label start:


    call Variables

    if introDone == True:
        jump hallway2


label intro:


    python:
        name = renpy.input("What's your name?")
        name = name.strip() or "Robbie"
        #$ playerName == name

    scene intro
    "{cps=25}It's been a month since I dropped out of trade school and lost my scholarship.{/cps}"
    "{cps=25}I've been looking for an apartment and a job, and I finally found something.{/cps}"
    "{cps=25}I found a run down apartment in the boonies and a shitty job. It's a kick to the balls but I've come back to work here.{/cps}"
    "{cps=25} {b}Fucking embarrassing{/b}{/cps}{cps=2}...  {/cps}{cps=15}but I need the job.{/cps}"

    $ introDone = False


label hallway2:

    scene hallway2
    hide screen gotohallway2

    if firstStart == True:

        show test_happy at right with dissolve

        emm "Hey anon! I'm so glad you came to school today! I was worried you were going to leave me alone again..."

        hide test_happy

        show test_embarrassed1 at right

        emm "Can I have lunch with you today?"

        $ firstStart = False

        menu:

            "Uhm, sorry I promised Belle Delphine I would have lunch with her... So...":
                call noToLunch
            "Sure.":
                call yesToLunch

        hide test_upset with dissolve
        
        hide test_embarrassed2 with dissolve

show screen gotohallway1

$ renpy.pause(hard=True)


label yesToLunch:

    hide test_embarrassed1

    show test_happy at right

    emm "Yay!"

    hide test_happy

    show test_embarrassed2 at right

    emm "I mean, uhm, see you then anon..."

    return

label noToLunch:

    hide test_embarrassed1

    show test_upset at right

    emm "Whatever Anon! You're such a jerk!"

    main "... What's that all about?"

    return

label Variables:

    $ firstStart = True
    $ introDone = False
    $ playerName = "Robbie"





label hallway1:

    scene hallway1

    hide screen gotohallway1

    show screen gotohallway2

    "if you are seeing this you fucked up or finished the game"

    $ renpy.pause(hard=True)

[_ticlock_]

Hi, Vennnot,

You did not put return statement in the label Variables:

Code: Select all

label Variables:
    ...
    return

Defining the variables in such a way is not a good idea. It is recommended to use the default statement to define variables and define statements to define constants. This way you won't have possible problems with save files and incompatibility of save files between different versions of the game. So you don't need the label Variables at all. Instead:

Code: Select all

default firstStart = True
default introDone = False
default playerName = "Robbie"

label start:
    if introDone == True:
        jump hallway2

[Imperf3kt]

You need to add a return at the end of your 'variables' label.

Right now, you call it at the start of the game, but it never returns and carries on into the next label, which happens to be hallway1

I wouldn't recommend doing your variables that way though, as it can cause issues with loading and future updates to the game.
Use default before the start label, instead.
Edit:
Looks like _ticlock_ beat me by a few seconds lol

[Vennnot]

Thanks guys! I appreciate it the help!

[m_from_space]

An hint regarding using images in Renpy:

You don't have to define images, but just put them into your ".../game/images" folder, e.g. "hoshi school smile.png" and "hoshi school upset.png". Renpy will automatically detect those images and assign variables (don't put _ between the words). In this case you then can do:

Code: Select all

show hoshi school smile at center
"Hey you!"
show hoshi school upset
"Now I am upset."

It is nearly never necessary to use "hide" on an image, since it automatically get's replaced with images that have the same "tag".