How do I create a small popup (hovering) journal for my players?

[olddog]

I've looked around at the screens and screen language section and I'm just miserably failing here.

I'd like to create a simple journal/to-do list popup that appears somewhere in the middle of the screen when the user clicks a journal button on the main screen.

It'd just be a basic bordered window with lines of text that can scroll. Items are just text like "Jan is waiting for you at the bar" and so forth to help guide the player.

Just a simple gray bordered box with multiple text lines that can scroll and a "Close" button (bonus if it can be closed by clicking the main screen behind the box.

[laure44]

Hey there,

Code: Select all

screen journal_screen:
    
    modal True
        
    imagebutton idle Solid((0,0,0,0.0)) action Hide("journal_screen") # If you click outside of the box, it will hide the screen
    
    frame: # simulates a border, there are probably better ways to do that though
        modal True
        background Frame(Solid("#aaa"), 10, 10)
        xsize 420 ysize 520
        xalign 0.5 yalign 0.5
        
        frame:
            background Frame(Solid("#fff"), 10, 10)
            xsize 400 ysize 500
            xalign 0.5 yalign 0.5 # centered
            
            viewport id "journal_viewport":
                xsize 350 ysize 400
                xalign 0.5 yalign 0.1
                draggable True mousewheel True
                
                vbox:
                    text "item 1" color "#000"
                    text "item 2" color "#000"
                    text "item 3" color "#000"
                    
            vbar value YScrollValue("journal_viewport") xalign 1.0
            textbutton "Close" action Hide("journal_screen") xalign 0.5 yalign 1.0

The imagebutton to show the screen :

Code: Select all

    imagebutton idle "gui/journal.png" action Show("journal_screen")

You can place that whereever you want

[olddog]

Absolutely perfect, thank you so much! It's exactly what I needed - super basic but enough to get me going and also give me something to build off of.

Wow - again, thank you!