Playing music in the choice/menu screen

[HideAndSeekVN]

I'm trying to implement a system like Life Is Strange where when the choice menu screen comes up, the currently playing music/sfx will fade to a lower volume and decision making background music will play on top.

I know how to do this in the script itself each time, but was hoping there's a better way to edit the screen itself so it happens automatically each time.

[Ocelot]

First of all, I would register channel on which choice music would play:

Code: Select all

init python:
    renpy.music.register_channel("choice_music", mixer="music", loop=True)

Then, I would modify existing choice screen, so it silences main music channel and play choice music when it shown. Then reverts everything back when it is hidden:

Code: Select all

screen choice(items):
    style_prefix "choice"
    vbox:
        for i in items:
            textbutton i.caption action i.action
    on "show"     action [Play(channel="choice_music", file="audio/choice.mp3", fadein=1.0), Function(renpy.music.set_volume, 0.2, delay=1.0, channel="music")]
    on "replace"  action [Play(channel="choice_music", file="audio/choice.mp3", fadein=1.0), Function(renpy.music.set_volume, 0.2, delay=1.0, channel="music")]
    on "hide"     action [Stop(channel="choice_music", fadeout=1.0),                         Function(renpy.music.set_volume, 1.0, delay=1.0, channel="music")]
    on "replaced" action [Stop(channel="choice_music", fadeout=1.0),                         Function(renpy.music.set_volume, 1.0, delay=1.0, channel="music")]

You can read more on used function and action in documentation:
https://www.renpy.org/doc/html/screen_a ... io-actions
https://www.renpy.org/doc/html/audio.html#functions

I have attached example project, so you could test it and see, how it is done.

[HideAndSeekVN]

Ahh, I think this is perfect! I added additional functions to silence the sound channel as well and it seems to work great. Thanks a bunch!!