[Solved] Is it possible to include a menu chunk into an existing menu, like this?

[henvu50]

I'm going to be using a lot of menu's, but part of the menu will always remain exactly the same. Is there a way to include a menu_chunk, so I don't have to re-type it over and over again? Like so...

Code: Select all

menu: 
    "A. Hello":
    "B. Hi":
    include("menu_chunk")

label menu_chunk:
    "Special: Static Function 1":
       $ func1()
    "Special: Static Function 2":     
       $ func2() 

[Ocelot]

1) Add an argument to the choice screen and pass your special functions as an argument:

Code: Select all

# menu_chunk = [("Special: Static Function 1", "func1"), ("Special: Static Function 2", "func2")]
menu (extra=menu_chunk ):
    "a":
        pass
# . . .
screen choice(items, extra=[]):
    # Usual stuff
    # After everything we add extra buttons:
    for name, function in extra:
        textbutton name action Function(function)

Or create a function to build your choice list and use renpy.display_menu to get your choices
https://www.renpy.org/doc/html/statemen ... splay_menu

[henvu50]

1) Add an argument to the choice screen and pass your special functions as an argument:

Code: Select all

# menu_chunk = [("Special: Static Function 1", "func1"), ("Special: Static Function 2", "func2")]
menu (extra=menu_chunk ):
    "a":
        pass
# . . .
screen choice(items, extra=[]):
    # Usual stuff
    # After everything we add extra buttons:
    for name, function in extra:
        textbutton name action Function(function)

Unfortunately the special functions passed as an argument are not part of the choice index, so if you press the arrow down keys, it won't cycle to the extra menu chunk choices. They're accessible by mouse, but not by keyboard.

Adding the special function choices into the menu choices index would make them part of the index, and the special function choices could then be accessed via the arrow keys. That's why I was hoping there was a way to include the menu choices in a chunk.

Still, this should help others who don't need the special function choices to be accessed via the keyboard.

On a side note, I actually did implement your solution to some degree already and include my special functions in the index, but I haven't figured out how to avoid the list out of range error when a special function choice is selected. This error occurs because when I select my custom function, it's looking to redirect to the menu: choices, but it sees a choice is not there. Not sure how to fix that. I have to somehow cancel the redirect and instead make it use it's own function, but the special function menu choice needs SetVariable logic in its action (in order to preserve the index so arrow keys work).

Or create a function to build your choice list and use renpy.display_menu to get your choices
https://www.renpy.org/doc/html/statemen ... splay_menu

I'm going to try this solution next, perhaps it will allow me to add the special function choices, but also include them in the index, so they can be access with the arrow keys in addition to the mouse.

I have a feeling this will solve my issue.

[Ocelot]

Works for me, all buttons are selectable from the keyboard:

Code: Select all

# screens.rpy
screen choice(items, extra=[]):
    style_prefix "choice"

    vbox:
        for i in items:
            textbutton i.caption action i.action
        for name, function in extra:
            textbutton name action Function(function)

# script.rpy
init python:
    def func1():
        renpy.jump("f1")

    def func2():
        renpy.jump("f2")

label start:
    $ menu_chunk = [("Special: Static Function 1", func1), ("Special: Static Function 2", func2)]
    menu (extra=menu_chunk ):
        "a":
            pass
    "this is a test"
    return

label f1:
    "F1"
    return
label f2:
    "F2"
    return

[Imperf3kt]

You could also make your own menu screen. The menu is just the choice screen with the text and arguments passed to it that it constructs buttons from and assigns actions.

[henvu50]

You could also make your own menu screen. The menu is just the choice screen with the text and arguments passed to it that it constructs buttons from and assigns actions.

I actually did do that. I got my own custom menu screen. It's working great so far.

Works for me, all buttons are selectable from the keyboard:

Code: Select all

# screens.rpy
screen choice(items, extra=[]):
    style_prefix "choice"

    vbox:
        for i in items:
            textbutton i.caption action i.action
        for name, function in extra:
            textbutton name action Function(function)

# script.rpy
init python:
    def func1():
        renpy.jump("f1")

    def func2():
        renpy.jump("f2")

label start:
    $ menu_chunk = [("Special: Static Function 1", func1), ("Special: Static Function 2", func2)]
    menu (extra=menu_chunk ):
        "a":
            pass
    "this is a test"
    return

label f1:
    "F1"
    return
label f2:
    "F2"
    return

Damn, I need to up my game. I want to get as black belt as you. Thanks again.

Now to figure out why my implementation didn't work!