[solved] Translation of strings

[thelastsecret]

I have a strange issue with translations of strings:
I have defined a function to say certain texts (I do this, since the speaker changes depending on a variable). It's something like:

Code: Select all

label hike_say(text):
    if hike=="Meilin":
        m "[text]"
    if hike=="Karina":
        k "[text]"
    return

This function gets called like that:

Code: Select all

call hike_say(_("That's a sample text."))

I would expect that _() makes sure that this text gets translated, and thus the translated text appears on screen. Indeed, the string is correctly listed in the translation file and I have added the translation. However, instead of the translated text, the original text is displayed.

And here are my questions:
1. Why on earth is this the case?
2. What can I do to change that?

I would be super happy if somebody could help me out here!

[m_from_space]

If you want to have variables inside strings translated, you have to add "!t".

Code: Select all

label hike_say(text):
    if hike=="Meilin":
        m "[text!t]"
    if hike=="Karina":
        k "[text!t]"
    return

[m_from_space]

By the way you could achieve the same thing writing, no need for an extra label.

Code: Select all

$ renpy.say(eval(hike), _("That's a sample text."))

edit: Don't use this, it's bad.

[PyTom]

Calling renpy.say and eval are quite bad.

[m_from_space]

Calling renpy.say and eval are quite bad.

Ok. Is there a reason? Is there a better solution?

[PyTom]

Eval is very slow, as Ren'Py does a lot of transformations to the Python to compile it - versus just looking up a name in a dict.

renpy.say can't be predicted, while a normal say statement can be. Predictability is a big win in Ren'Py.

[m_from_space]

Yeah okay, that makes sense.

[thelastsecret]

Thanks a lot, that was great help! I'll try it out asap!

[thelastsecret]

I have changed the function as described:

Code: Select all

label hike_say(text):
    if hike=="Meilin":
        m "[text!t]"
    if hike=="Karina":
        k "[text!t]"
    return

Now most cases work, but not unfortunately, not all, since there is one more special case, namely constructions like this:

Code: Select all

call hike_say(_("This is a sample, addressing the player with the player's name in a variable: Hello ")+playername+"!")

In this case, the text still doesn't get translated, although I have a translation for the string "This is a sample, addressing the player with the player's name in a variable: Hello " in the translation file (generated by Ren'py). I think that's because it looks for a translation of "This is a sample, addressing the player with the player's name in a variable: Hello Anna!" (if, let's say, playername=="Anna") and doesn't find it this string.
But how can I fix that? I'm clueless...

Edit: The other suggested hack gives the same result.

[m_from_space]

Don't use my hack since Pytom knows what he's talking about.

For your latest issue you should think about how renpy translates: It automatically translates strings that exactly matches the ones inside the translation file when it shows that string on screen. Since you alter your string before it can be translated, it will not find it. (You put "playername" + "!" at the end.)

I suggest:

Code: Select all

call hike_say(_("This is a sample, addressing the player with the player's name in a variable: Hello {nw}"))
extend "[playername]!"

edit: Don't forget to update your translation file, since I added a "{nw}".

[Ocelot]

You can write your string with substitution inside like call hike_say(_("This is a sample, addressing the player with the player's name in a variable: Hello [playername]!") and use [ . . . !ti] to interpolate translated string.

But you can just assign your speaker to variable directly to avoid most of that hassle.

Code: Select all

# was
$ hike = "Meilin":
call hike_say("some text . . .")
$ hike = "Karina"
call hike_say("other text . . .")

# now
$ hike = m
hike "some text . . ."
$ hike = k
hike "other text . . ."

[thelastsecret]

I suggest:

Code: Select all

call hike_say(_("This is a sample, addressing the player with the player's name in a variable: Hello {nw}"))
extend "[playername]!"

Okay, that's an elegant workaround, thank you!. I should have come up with that, too. Looks like I'm not smart enough.
EDIT: However, it doesn't work as easily! Or actually, at first it does, so the text translates and is displayed, but then it's immediately replaced by:

Code: Select all

[text!t][playername]?

It took me a while to find the reason for that, although it's fairly easy: the variable text is only defined in the function, but the extend command happens after the function had been called in the main program, so Ren'py doesn't know the variable text then and so just prints the "source code".
I found a fix for that, however: I just define the variable in the main program with the same value:

Code: Select all

$text="This is a sample, addressing the player with the player's name in a variable: Hello {nw}"
call hike_say(_("This is a sample, addressing the player with the player's name in a variable: Hello {nw}"))
extend "[playername]!"

Then it finally works!
Fortunately, there are only three such instances where the player is addressed directly, otherwise that would be tedious.

So thanks again for the help! That was surprisingly tricky, I must say...

[thelastsecret]

You can write your string with substitution inside like call hike_say(_("This is a sample, addressing the player with the player's name in a variable: Hello [playername]!") and use [ . . . !ti] to interpolate translated string.

Okay, I need to digest this interpolation thingy, but it sounds cool.

But you can just assign your speaker to variable directly to avoid most of that hassle.

Code: Select all

# was
$ hike = "Meilin":
call hike_say("some text . . .")
$ hike = "Karina"
call hike_say("other text . . .")

# now
$ hike = m
hike "some text . . ."
$ hike = k
hike "other text . . ."

You can do - WHAT???
Sometimes Ren'py is like magic!
However, this does not work completely, since it just prints "m" instead of "Meilin" as the speaker's name. Also the color of the speaker is just the standard yellow one.

[philat]

You probably used $ hike = "m" instead of $ hike = m.

[thelastsecret]

You probably used $ hike = "m" instead of $ hike = m.

*face palm*
Yep, that's it. This would have been the easy solution. Just define a new speaker hike wither as m or k and then use that throughout this section. I'm certified stupid.
Next time I'll program something like this, I know how to save my time and make the code simple.
Thank you so much!