Add Sepia Filter To LayeredImage?

[lking22]

Okay, there HAS to be an easier way to do this than what I have. So far I've got something like this:

Code: Select all

layeredimage ply:
    always:
        Null(width=1)
    group expr:
        attribute flat default:
            Null(width=1)
        attribute anxious:
            Null(width=1)
    group arms:
        attribute down default:
            Null(width=1)
        attribute up:
            Null(width=1)


layeredimage side ply:
    if memory:
        im.Sepia("side_ply_base.png")
    else:
        "side_ply_base.png"
    group expr:
        attribute flat default:
            ConditionSwitch(
                "memory == True", im.Sepia("side_ply_expr_flat.png"),
                "True", "side_ply_expr_flat.png")
        attribute anxious:
            ConditionSwitch(
                "memory == True", im.Sepia("side_ply_expr_anxious.png"),
                "True", "side_ply_expr_anxious.png")
    group arms:
        attribute down default:
            ConditionSwitch(
                "memory == True", im.Sepia("side_ply_arms_down.png"),
                "True", "side_ply_arms_down.png")
        attribute up:
            ConditionSwitch(
                "memory == True", im.Sepia("side_ply_arms_up.png"),
                "True", "side_ply_arms_up.png")

Which is unwieldy already and she's barely got any expressions at all. Also it doesn't actually work half the time? Basically, if I open the game and start it from the main menu, the images don't display at all when I get to the scene where 'memory' is true. Not even an error or silhouette or anything. However, if I shift+R to reload at any point in the game (even outside of memory scenes), then it displays perfectly fine?

Honestly I'm just very confused.

[philat]

You can use matrixcolor transforms instead of image manipulators now. That said, assuming you would be showing the whole "memory" scene in sepia, wouldn't it be simpler to just filter the whole scene?

Code: Select all

transform sepia:
    matrixcolor SepiaMatrix() #https://www.renpy.org/doc/html/matrixcolor.html#SepiaMatrix

label start_memory:

    camera at sepia #https://www.renpy.org/doc/html/displaying_images.html#camera-and-show-layer-statements
    scene your_background
    show your_image
    "This is a memory."
    camera
    "Memory over."

[lking22]

Oh my god, the 'camera at sepia' thing is so much simpler! Honestly I just started using RenPy again today after a few years' break, so idk if that's new or not, but it's going to be a huge help. Thanks so much!