Blinking Effect Question

[ReAnimator]

Hello.
I want this blinking animation to have fadein and out effect.
Currently trans.alpha is set to 1.0 and 0.0 respectively so it shows and hides instantly.
Is there any way to achieve this?

Code: Select all

init python:
    def show_op(trans, st, at):
        if st < 1 / x:
            trans.alpha = 1.0
            return 0
        else:
            return None

    def hide_op(trans, st, at):
        if st < 1 / x:
            trans.alpha = 0.0
            return 0
        else:
            return None

screen blinking():
    add Solid("#ffff"):
        at transform:
            function show_op
            function hide_op
            repeat
            
    timer 1.0 action SetVariable("x", x + 1) repeat True

label start:
    $ x = 1 
    show screen blinking
    "I want to add fadein and out effect to trans.alpha."
    return
    

[Imperf3kt]

you could use "on show" within the screen to add the transition.
https://www.renpy.org/doc/html/screens.html#on

[ReAnimator]

Yeah,
To be exact I want it to look like attached video.
Can it be done with on show statement?
I really can't figure it out.

[Ocelot]

You can make a custom warper ( https://www.renpy.org/doc/html/atl.html ... -statement ) and use it in transform:

Code: Select all

init python:
    def Blink(repetitions):
        def blink(t):
            from math import pi, cos
            t = t * t * (pi * 2 * repetitions - pi)
            w = cos(t)
            return (w + 1) / 2 # [-1, 1] → [0, 1]
        return blink

define blink = Blink(20)

transform induce_seizure:
    alpha 1.0
    warp blink 10 alpha 0.0

screen blinking():
    add Solid("#ffff") at induce_seizure

label start:
    show screen blinking
    "I want to add fadein and out effect to trans.alpha."
    return

[ReAnimator]

Brilliant!
You know what, there's no way I can figure this out on my own. How can you do that, man... this makes me really sad... still no idea about that math code... lol
Thanks for your help. This is exactly I want.

[m_from_space]

transform induce_seizure:

Thanks for the laugh.