How to change main menu screen according to system time?

[Alvsvartr]

Hi all,

So basically, I plan to change the main menu background four times a day:
- from 6:00 AM to 11:00 AM - the first image
- from 11:00 AM to 06:00 PM - the second image
- from 06:00 PM to 09:00 PM - the third image
- from 09:00 PM to 06:00 AM - the fourth image

It doesn't look like an utterly impossible task, yet I have no particular idea.

Could you please help me with how I can achieve this? Thanks.

[m_from_space]

Since Renpy is in symbiosis with Python, you can just use Python to get the current time via the datetime module. Format it to your needs and then change your main_menu screen according to the variable.

Code: Select all

init python:
    from datetime import datetime
    
screen main_menu():
    python:
        time_object = datetime.now()
        time_hours = int(time_object.strftime("%H"))
        time_minutes = int(time_object.strftime("%M"))

    if time_hours >= 6 and time_hours < 11:
        ...

[Alvsvartr]

Since Renpy is in symbiosis with Python, you can just use Python to get the current time via the datetime module. Format it to your needs and then change your main_menu screen according to the variable.

Thank you for your reply.
I'm trying to use it correctly, but it doesn't want to work fine.

So, as the first step, I changed gui.rpy in the following way (I'm not sure in it):

Code: Select all

define gui.main_menu_background = ["images/start1.png", "images/start2.png", "images/start3.png", "images/start4.png"]

Then I went to screens.rpy and used your suggestion as follows:

Code: Select all

init python:
    from datetime import datetime

screen main_menu():
    python:
        time_object = datetime.now()
        time_hours = int(time_object.strftime("%H"))
        time_minutes = int(time_object.strftime("%M"))

    if time_hours >= 6 and time_hours < 11:
        show start1
    if time_hours >= 11 and time_hours < 18:
        show start2
    if time_hours >= 18 and time_hours < 21:
        show start3
    if time_hours >= 21 and time_hours < 6:
        show start4
  

I've tried to use direct ways to start*.png files, but the result still is a mistake.
Be so kind as to help me. Thanks.

[m_from_space]

So, as the first step, I changed gui.rpy in the following way (I'm not sure in it):

Code: Select all

define gui.main_menu_background = ["images/start1.png", "images/start2.png", "images/start3.png", "images/start4.png"]

No, please revert that, we won't need that config variable, since we replace it anyway. Also you cannot just put a list of strings there and hope it will do something.

Code: Select all

define gui.main_menu_background = None

Alter the main menu screen inside screens.rpy:

Code: Select all

init python:
    from datetime import datetime

screen main_menu():
    tag menu
    style_prefix "main_menu"

    python:
        time_object = datetime.now()
        time_hours = int(time_object.strftime("%H"))

    if time_hours >= 6 and time_hours < 11:
        add "start1"
    elif time_hours >= 11 and time_hours < 18:
        add "start2"
    elif time_hours >= 18 and time_hours < 21:
        add "start3"
    else:
        add "start4"
        
    use navigation

You might want to do the same inside "game_menu" screen.

[Imperf3kt]

Note that the above won't reflect changes until the player restarts the game and the time is checked at runtime. There is a way to make it check in real time, but I don't remember the method currently.

[m_from_space]

Note that the above won't reflect changes until the player restarts the game and the time is checked at runtime. There is a way to make it check in real time, but I don't remember the method currently.

Isn't this screen redrawn like other screens? Like when you go to some game_menu screen and back to the main_menu? I mean it's not like this is supposed to change when the player sits hours inside the menu, right?

The time is checked every time the screen is drawn, not just at the start of the game.

edit: You could let it check in "realtime" including a timer that loops and checks after every minute if you want to.

[Alvsvartr]

Code: Select all

define gui.main_menu_background = None

Oh, I see! I was a bit tired at the moment and added just a transparent image here =)) I've used manual selection to find the command "add". It was something! Thank you!

And I'd like to add one more variant to make things going:

At first, let's go to the gui.rpy:

Code: Select all

init python:
    import datetime

define gui.main_menu_background = ["images/start1.png", "images/start2.png", "images/start3.png", "images/start4.png"]

Then we should go to the screens.rpy, and make the following:

Code: Select all

screen main_menu():

    ## This ensures that any other menu screen is replaced.
    tag menu

    style_prefix "main_menu"

    # <<<
    #add gui.main_menu_background
    $ ct = datetime.datetime.now().hour
    if 6 <= ct < 11:
        add gui.main_menu_background[0]
    elif 11 <= ct < 18:
        add gui.main_menu_background[1]
    elif 18 <= ct < 21:
        add gui.main_menu_background[2]
    else:
        add gui.main_menu_background[3]
    # >>>

    ## This empty frame darkens the main menu.
    frame:
        [...]

And that's it =) All thanks go to anne O'nymous from f95zone.to.

Moreover, there's one more alternative:

Code: Select all

init python:
    import datetime

define gui.main_menu_background = ConditionSwitch("datetime.datetime.now().hour >= 21", "gui/main_menu_night.png",
    "datetime.datetime.now().hour >= 18", "gui/main_menu_evening.png",
    "datetime.datetime.now().hour >= 11", "gui/main_menu_afternoon.png",
    "datetime.datetime.now().hour >= 6", "gui/main_menu_morning.png",
    "True", "gui/main_menu_night.png")

Thanks go to crabsinthekitchen from f95zone.to.

So, we have at least three alternatives, yet we can choose all of them.

[Alvsvartr]

Note that the above won't reflect changes until the player restarts the game and the time is checked at runtime. There is a way to make it check in real time, but I don't remember the method currently.

I checked it, and the solution provided by anne O'nymous changes the image in real-time.

[m_from_space]

Note that the above won't reflect changes until the player restarts the game and the time is checked at runtime. There is a way to make it check in real time, but I don't remember the method currently.

I checked it, and the solution provided by anne O'nymous changes the image in real-time.

Well, it's basically the same solution as I proposed, I just didn't know that you can get the hours out of datetime this easily. My solution doesn't need a list on the other hand, I don't get why this was even suggested. You just don't need a config variable that is there for making changes more easy.

The ConditionSwitch is neat, but on the other hand calls datetime.now() multiple times, so it's not the most efficient (not that it really matters).