[Solved] Add "click to continue" content warning screen to splashscreen?

[yon]

I want to display a screen within my splashscreen that displays once, and does not continue until you click a button to proceed. This is because I want to display a content warning, so that the player must agree that they're willing to see that content.

I have the splashscreen, and I have the content warning screen, and that all works just fine. The issue is that it isn't waiting for the screen's buttons to be clicked before continuing. If I add a pause, it essentially makes you click twice to continue, for some reason. If I include no pause, it just displays the screen for a little bit, then automatically continues to the main menu.

It's also been skipping over the text after the conditional block, for some reason.

Here is the splashscreen:

Code: Select all

label splashscreen:

    scene black

    $ persistent.shown_warning = False # This is just so I can see it every time it starts up for testing purposes

    if not persistent.shown_warning:
        # Show warning here
        $ persistent.shown_warning = True
        show screen content_warning with dissolve


    show text "A story by Tetra Yon" at truecenter with dissolve
    with Pause(2)

    hide text with dissolve
    with Pause(1)

    return

And here is the screen:

Code: Select all

screen content_warning:

    frame:
        xsize 1280 # The BG image takes up the entire screen
        ysize 720
        xpos 0
        ypos 0
        padding (0, 0) # Manually reset padding
        background Frame("gui/overlay/pause_bg.png")

        vbox:
            text '{size=33}(Content warnings here, asks if you want to proceed){/size=33}':
                pos (370, 40)
                xsize 540 # sets line length
                text_align 0.5 # align center

        imagebutton:
            auto "gui/button/pause_button_left_%s.png"
            # YES button
            focus_mask True
            pos (370,440)
            action Return(), With(dissolve)

        imagebutton:
            auto "gui/button/pause_button_right_%s.png"
            # NO button
            focus_mask True
            pos (650,440)
            action Quit()

        text "{size=35}Yes{/size}":
            pos (380, 455)
            min_width 240 # sets line length
            text_align 0.5 # align center

        text "{size=35}No{/size}":
            pos (660, 455)
            min_width 240 # sets line length
            text_align 0.5 # align center

[Imperf3kt]

The splash screen isn't really designed for this. It's also somewhat of a misnomer, being a label rather than a screen.

Instead, I would use label before_main_menu to call your content warning.

[yon]

I tried swapping it with that label. It's still skipping directly through the content warning screen without stopping. It displays it for a second, and then goes away.

[Ocelot]

Call screen instead of showing it. Right now you have nothing stopping the flow of the game.
IN addition, you should make screen modal, this should stop other interactions too.

[yon]

Thank you, call made the screen stick around.

Now I just need to make it not skip over the other text once you click "Yes".

I tried swapping Return() for Hide("content_warning") as the Yes button's action, but that just showed a black screen instead of progressing to the text.

Should I have it call the before_main_menu instead, so it'll skip the content warning and go straight to the "splash screen" text?

[yon]

I decided to put the text before the screen, and that seems to work, but I still don't know why it did that to begin with.

Here's what I'm using now:

Code: Select all

label before_main_menu:

    scene black with Pause(1)

    show text "A story by Tetra Yon" at truecenter with dissolve
    with Pause(2)

    hide text with dissolve
    with Pause(1)

    $ persistent.shown_warning = False # For testing purposes

    if not persistent.shown_warning:
        # Show warning here
        $ persistent.shown_warning = True
        call screen content_warning with dissolve

    return

Code: Select all

screen content_warning:

    modal True

    frame:
        xsize 1280
        ysize 720
        xpos 0
        ypos 0
        padding (0, 0) # Manually reset padding
        background Frame("gui/overlay/pause_bg.png")

        vbox:
            text '{size=33}(Content Warning){/size=33}':
                pos (370, 40)
                xsize 540 # sets line length
                text_align 0.5 # align center

        imagebutton:
            auto "gui/button/pause_button_left_%s.png"
            # YES button
            focus_mask True
            pos (370,440)
            action Return(), With(dissolve)

        imagebutton:
            auto "gui/button/pause_button_right_%s.png"
            # NO button
            focus_mask True
            pos (650,440)
            action Quit()

        text "{size=35}Yes{/size}":
            pos (380, 455)
            min_width 240 # sets line length
            text_align 0.5 # align center

        text "{size=35}No{/size}":
            pos (660, 455)
            min_width 240 # sets line length
            text_align 0.5 # align center