Action to move image and change variable on a Screen

[lindsay-jb]

I'm working on a game with a dress-up screen. On this screen, I have an image of the main character and two buttons. I want to make the MC image move left/right offscreen, change into a new outfit, and move out from the other side of the screen when you press the buttons.

Code: Select all

screen outfit_game():
    default move = truecenter

    add "mc big" at move

    imagebutton:
            idle "arrow left.png"
            action (
                    SetScreenVariable("move", toOffscreenLeft),
                    Function(PreviousOutfit),
                    SetScreenVariable("move", fromOffscreenRight),
                    SetScreenVariable("move", truecenter)
            )

    imagebutton:
            idle "arrow right.png"
            action (
                    SetScreenVariable("move", toOffscreenRight),
                    Function(NextOutfit),
                    SetScreenVariable("move", fromOffscreenLeft),
                    SetScreenVariable("move", truecenter)
            )

My current code looks like this. The problem is that all the actions are fired off in a way that the next action doesn't wait for the completion of the previous, so it appears as if the transforms aren't applied at all (because they're quickly overwritten).
How do I solve this problem? Is there a way to insert a variable change into an ATL transform or to add a callback to an ATL transform without breaking it, or maybe a way to make an action wait for the completion of the previous action? Or is there a better solution?

[enaielei]

Screen timers would probably help.
Additionally, containing the transforms inside one transform might work.

Code: Select all

init python:
    def tfn(tr, st, at, callback=None):
        fn = callback
        if callable(fn):
            fn()
            renpy.restart_interaction()

transform move_left(fn=None):
    toOffscreenLeft
    pause 1.0 # how long do we need to wait before doing the next transform?
    function renpy.partial(tfn, callback=fn)
    fromOffscreenRight
    pause 1.0
    truecenter
    
transform move_right(fn=None):
    toOffscreenRight
    pause 1.0
    function renpy.partial(tfn, callback=fn)
    fromOffscreenLeft
    pause 1.0
    truecenter

Then in your code.

Code: Select all

imagebutton:
    idle "arrow left.png"
    action SetScreenVariable("move", move_left(PreviousOutfit))

Note: Untested

[lindsay-jb]

That worked perfectly, thank you so much!