[SOLVED] If statement in menu??

[Swein]

Code: Select all

label try:
    default option2 = True
    menu tavern1:
        if option2:
            s "I guess you're new around here, what do you want to do?"
        else:
            s "Ok, now what do you want to do?"
        "I want to find a job":
            $ gift = "job"
            "I'll search a job for you!"
        "I want to find a witch contract" if option2:
            $ option2 = False
            "Oh god sake! I never ever interest this things, they're haunted."
            jump tavern1

What I want to do is change the sentence the character says below when the menu options again appear after "jump". However, I couldn't do it.

[Tess]

A little clunky I'll admit, but I think this'll work.

Code: Select all

default option2 = True #Can be defined anywhere, just make sure it comes before the try label

label try:
	$question = "I guess you're new around here, what do you want to do?" if option2 else "Ok, now what do you want to do?"
	menu tavern1:
        	"[question]"
        	"I want to find a job":
            		$ gift = "job"
            		"I'll search a job for you!"
        	"I want to find a witch contract" if option2:
        		$ option2 = False
            		"Oh god sake! I never ever interest this things, they're haunted."
            		jump try #Jump to the try label instead of jumping to the tavern1 menu statement so we hit our question assembly again

[_ticlock_]

What I want to do is change the sentence the character says below when the menu options again appear after "jump". However, I couldn't do it.

if statements does not work this way in the choice menu.

I suggest to put if statement before the choice menu and then use extend expression in the choice menu. Also, add no-wait tag nw at the end, it will dismiss current say statement and you go straight to the choice menu with the correct question.

Code: Select all

default option2 = True

label try:

label tavern1:
    if option2:
        s "I guess you're new around here, what do you want to do?{nw}"
    else:
        s "Ok, now what do you want to do?{nw}"
    menu:
        extend ""
        "I want to find a job":
            $ gift = "job"
            "I'll search a job for you!"
        "I want to find a witch contract" if option2:
            $ option2 = False
            "Oh god sake! I never ever interest this things, they're haunted."
            jump tavern1

[Swein]

What I want to do is change the sentence the character says below when the menu options again appear after "jump". However, I couldn't do it.

if statements does not work this way in the choice menu.

I suggest to put if statement before the choice menu and then use extend expression in the choice menu. Also, add no-wait tag nw at the end, it will dismiss current say statement and you go straight to the choice menu with the correct question.

Code: Select all

default option2 = True

label try:

label tavern1:
    if option2:
        s "I guess you're new around here, what do you want to do?{nw}"
    else:
        s "Ok, now what do you want to do?{nw}"
    menu:
        extend ""
        "I want to find a job":
            $ gift = "job"
            "I'll search a job for you!"
        "I want to find a witch contract" if option2:
            $ option2 = False
            "Oh god sake! I never ever interest this things, they're haunted."
            jump tavern1

You are my super hero, thanks!

[Swein]

A little clunky I'll admit, but I think this'll work.

Code: Select all

default option2 = True #Can be defined anywhere, just make sure it comes before the try label

label try:
	$question = "I guess you're new around here, what do you want to do?" if option2 else "Ok, now what do you want to do?"
	menu tavern1:
        	"[question]"
        	"I want to find a job":
            		$ gift = "job"
            		"I'll search a job for you!"
        	"I want to find a witch contract" if option2:
        		$ option2 = False
            		"Oh god sake! I never ever interest this things, they're haunted."
            		jump try #Jump to the try label instead of jumping to the tavern1 menu statement so we hit our question assembly again

I just saw that, works too, and the extend method also works. Thank you. I appreciate that! Renpy won't die as long as there are people like you