A different preferences/load/save menu for the ma...(SOLVED)

[clannadman]

How can I customize the Yes/No screens using screens.rpy? Before, I used a command in option.rpy:

Code: Select all

 layout.ARE_YOU_SURE : "yesno_are_you_sure.png"
  layout.DELETE_SAVE : "yesno_delete_save.png"
  layout.OVERWRITE_SAVE : "yesno_overwrite_save.png"
  layout.LOADING : "yesno_loading.png"
  layout.QUIT : "yesno_quit.png"
  layout.MAIN_MENU : "yesno_main_menu.png"  

However, I know this won't work. So far I've got:

Code: Select all

screen yesno_prompt:

    imagemap:
        ground "yesno_ground.png"
        idle "yesno_idle.png"
        hover "yesno_hover.png"
        
        hotspot (254, 214, 306, 246) clicked("Yes")
        hotspot (338, 214, 386, 246) clicked("No")
    

What do I need to do to offer the different yes/no menu choices?

[Alex]

What do I need to do to offer the different yes/no menu choices?

Well, I can suggest one of two options:
1) Just show prompt message over your imagemap

Code: Select all

screen yesno_prompt:
    modal True
    imagemap:
        ground "yesno_ground.png"
        idle "yesno_idle.png"
        hover "yesno_hover.png"
        
        hotspot (254, 214, 306, 246) clicked yes_action
        hotspot (338, 214, 386, 246) clicked no_action

    label _(message):
            xalign 0.5
            yalign 0.3

2) Show different imagemaps for different prompts:

Code: Select all

screen yesno_prompt:
    modal True

    if message == layout.OVERWRITE_SAVE:
        imagemap:
        ground "yesno_OVERWRITE_SAVE_ground.png"
        idle "yesno_OVERWRITE_SAVE_idle.png"
        hover "yesno_OVERWRITE_SAVE_hover.png"
        
        hotspot (254, 214, 306, 246) clicked yes_action
        hotspot (338, 214, 386, 246) clicked no_action

    elif message == layout.QUIT:
        imagemap:
        ground "yesno_QUIT_ground.png"
        idle "yesno_QUIT_idle.png"
        hover "yesno_QUIT_hover.png"
        
        hotspot (254, 214, 306, 246) clicked yes_action
        hotspot (338, 214, 386, 246) clicked no_action

    else:
    # etc.

http://www.renpy.org/doc/html/screen_sp ... sno-prompt

[clannadman]

Can you tell me how the new hotspots work for screens?

Thankyou so much for your help so far

[Alex]

They work the same way, but an old hotspot was (x1, y1, x2, y2) - that are coordinates of top left and bottom right corners of active area, and new one is (x, y, width, height) - the coordinates of top left corner and the width and the height of active area.

http://www.renpy.org/doc/html/screens.h ... statements
(read first about new imagemaps, 'cause hotspots definition has changed).

You are welcome...))

[clannadman]

Okay thankyou

I'm currently working on the filepicker for Load/Save screens however I can't seem to get the coding right:

Code: Select all

screen file_picker:

    
    imagemap:
        ground "loadsave_ground.png"
        idle "loadsave_idle.png"
        hover "loadsave_hover.png"
        selected_idle "loadsave_selected_idle.png"
        selected_hover "loadsave_selected_hover.png"
        
        hotspot (249, 72, 48, 23) clicked FilePage("previous")
        hotspot (309, 72, 55, 23) clicked FilePage("page_auto")
        hotspot (380, 72, 14, 23) clicked FilePage("page_1")
        hotspot (409, 72, 19, 23) clicked FilePage("page_2")
        hotspot (440, 72, 18, 23) clicked FilePage("page_3")
        hotspot (471, 72, 18, 23) clicked FilePage("page_4")
        hotspot (501, 72, 18, 23) clicked FilePage("page_5")
        hotspot (531, 72, 55, 23) clicked FilePage("next")
                               
        hotspot (246, 110, 342, 63) clicked FileAction("slot_0")
        hotspot (246, 182, 342, 63) clicked FileAction("slot_1")
        hotspot (246, 253, 342, 64) clicked FileAction("slot_2")
        hotspot (246, 326, 342, 64) clicked FileAction("slot_3")
        
        for i in range (1, 4):
        
            button:
                    action FileAction(i)
                    xfill True
                    style "large_button"

                    has hbox
                    # Add the screenshot.
                    add FileScreenshot(i)
                    
                    # Format the description, and add it as text.
                    $ description = "% 2s. %s\n%s" % (
                    FileSlotName(i, columns * rows),
                    FileTime(i, empty=_("Empty Slot.")),
                    FileSaveName(i))

                    text description

                    key "save_delete" action FileDelete(i)
        
        

Any suggestions? I'm trying to the get the details and screenshot of the saves/loads in the slots but I keep getting tracebacks.

[Alex]

Shhh... I've searched some on forum... and found a good example of code!
Hope Uncle Mugen won't mind if we borrow some code samples...))
http://lemmasoft.renai.us/forums/viewto ... f=8&t=9641
So, clannadman, you don't need the part of code that related to buttons at all.
You need to show screenshots and its descriptions inside the hotspots. If we combine your code with the part of mugenjohncel's code, we'll get

Code: Select all

screen load_save_slot:
    $ file_text = "% 2d. %s\n  %s" % (number, FileTime(number, empty="Empty slot."), FileSaveName(number))

    add FileScreenshot(number) xpos 0 ypos 0
    text file_text xpos 0 ypos 0

screen file_picker:

    
    imagemap:
        ground "loadsave_ground.png"
        idle "loadsave_idle.png"
        hover "loadsave_hover.png"
        selected_idle "loadsave_selected_idle.png"
        selected_hover "loadsave_selected_hover.png"
        
        hotspot (249, 72, 48, 23) clicked FilePage("previous")
        hotspot (309, 72, 55, 23) clicked FilePage("page_auto")
        hotspot (380, 72, 14, 23) clicked FilePage("page_1")
        hotspot (409, 72, 19, 23) clicked FilePage("page_2")
        hotspot (440, 72, 18, 23) clicked FilePage("page_3")
        hotspot (471, 72, 18, 23) clicked FilePage("page_4")
        hotspot (501, 72, 18, 23) clicked FilePage("page_5")
        hotspot (531, 72, 55, 23) clicked FilePage("next")

        hotspot (246, 110, 342, 63) clicked FileAction(0):
            use load_save_slot(number=0)
        hotspot (246, 182, 342, 63) clicked FileAction(1):
            use load_save_slot(number=1)
        hotspot (246, 253, 342, 64) clicked FileAction(2):
            use load_save_slot(number=2)
        hotspot (246, 326, 342, 64) clicked FileAction(3):
            use load_save_slot(number=3)

[clannadman]

I've copied the code as stated and it's working There's an issue however with screenshot size and also the text that is displayed:

Code: Select all

screen load_save_slot:
    $ file_text = "% 2d. %s\n  %s" % (number, FileTime(number, empty="Empty slot."), FileSaveName(number))

    add FileScreenshot(number) xpos 0 ypos 0
    text file_text xpos 0 ypos 0

screen file_picker:

    imagemap:
        ground "loadsave_ground.png"
        idle "loadsave_idle.png"
        hover "loadsave_hover.png"
        selected_idle "loadsave_selected_idle.png"
        selected_hover "loadsave_selected_hover.png"
        
        hotspot (249, 72, 48, 23) clicked FilePage("previous")
        hotspot (309, 72, 55, 23) clicked FilePage("page_auto")
        hotspot (380, 72, 14, 23) clicked FilePage("page_1")
        hotspot (409, 72, 19, 23) clicked FilePage("page_2")
        hotspot (440, 72, 18, 23) clicked FilePage("page_3")
        hotspot (471, 72, 18, 23) clicked FilePage("page_4")
        hotspot (501, 72, 18, 23) clicked FilePage("page_5")
        hotspot (531, 72, 55, 23) clicked FilePage("next")
                               
        hotspot (246, 110, 342, 63) clicked FileAction(0):
            use load_save_slot(number=0)
        hotspot (246, 182, 342, 63) clicked FileAction(1):
            use load_save_slot(number=1)
        hotspot (246, 253, 342, 64) clicked FileAction(2):
            use load_save_slot(number=2)
        hotspot (246, 326, 342, 64) clicked FileAction(3):
            use load_save_slot(number=3)
    
init -2 python:
    
    style.file_picker_ss_window.xalign = 0.9
    style.file_picker_ss_window.yalign = 0.5
    style.file_picker_text_window.xalign = 0.1
    style.file_picker_text_window.yalign = 0.5    
    config.thumbnail_width = 67
    config.thumbnail_height = 51

I've worked out screenshots but the text displayed for each save file follows the 0. 1. 2. 3. of the code rather than altering the number of the save for each page:

This example is on Page 3 and the save slot should be 11. rather than 2.

[Alex]

Oh, I had to spent some time to understand how it works myself.
And this is the code I got

Code: Select all

screen my_load:

    # This ensures that any other menu screen is replaced.
    tag menu

    use my_navigation
    imagemap:
        ground "loadsave_ground.png"
        idle "loadsave_idle.png"
        hover "loadsave_hover.png"
        selected_idle "loadsave_selected_idle.png"
        selected_hover "loadsave_selected_hover.png"
        
        hotspot (249, 72, 48, 23) clicked FilePagePrevious()
        hotspot (309, 72, 55, 23) clicked FilePage("auto")
        hotspot (380, 72, 14, 23) clicked FilePage(1)
        hotspot (409, 72, 19, 23) clicked FilePage(2)
        hotspot (440, 72, 18, 23) clicked FilePage(3)
        hotspot (471, 72, 18, 23) clicked FilePage(4)
        hotspot (501, 72, 18, 23) clicked FilePage(5)
        hotspot (531, 72, 55, 23) clicked FilePageNext(5)
                               
        hotspot (246, 110, 342, 63) clicked FileLoad(1):
            use load_save_slot(number=1)
        hotspot (246, 182, 342, 63) clicked FileLoad(2):
            use load_save_slot(number=2)
        hotspot (246, 253, 342, 64) clicked FileLoad(3):
            use load_save_slot(number=3)
        hotspot (246, 326, 342, 64) clicked FileLoad(4):
            use load_save_slot(number=4)
            
screen my_save:

    # This ensures that any other menu screen is replaced.
    tag menu

    use my_navigation
    imagemap:
        ground "loadsave_ground.png"
        idle "loadsave_idle.png"
        hover "loadsave_hover.png"
        selected_idle "loadsave_selected_idle.png"
        selected_hover "loadsave_selected_hover.png"
        
        hotspot (249, 72, 48, 23) clicked FilePagePrevious()
        hotspot (309, 72, 55, 23) clicked FilePage("auto")
        hotspot (380, 72, 14, 23) clicked FilePage(1)
        hotspot (409, 72, 19, 23) clicked FilePage(2)
        hotspot (440, 72, 18, 23) clicked FilePage(3)
        hotspot (471, 72, 18, 23) clicked FilePage(4)
        hotspot (501, 72, 18, 23) clicked FilePage(5)
        hotspot (531, 72, 55, 23) clicked FilePageNext(5)
                               
        hotspot (246, 110, 342, 63) clicked FileSave(1):
            use load_save_slot(number=1)
        hotspot (246, 182, 342, 63) clicked FileSave(2):
            use load_save_slot(number=2)
        hotspot (246, 253, 342, 64) clicked FileSave(3):
            use load_save_slot(number=3)
        hotspot (246, 326, 342, 64) clicked FileSave(4):
            use load_save_slot(number=4)
        
        
            
screen load_save_slot:
    $ file_text = "% 2s. %s\n%s" % (
                        FileSlotName(number, 4),
                        FileTime(number, empty=_("Empty Slot.")),
                        FileSaveName(number))


    add FileScreenshot(number) xpos 0 ypos 0
    text file_text xpos 0 ypos 0
    
    key "save_delete" action FileDelete(number)

Numbers for slots was changed - Ren'py numerates them from 1.
"file_text" format was taken from original "screens.rpy".
Page names should be "auto", "quick" or an integer, so all "page_<number>" was replaced with integers.
http://www.renpy.org/doc/html/screen_ac ... e#FilePage

[clannadman]

I get the following and I think it's referring to the load_save_slot screen:

Code: Select all

I'm sorry, but an uncaught exception occurred.

While running game code:
  File "game/screens.rpy", line 314, in python
    
  File "game/screens.rpy", line 301, in python
                use load_save_slot(number=1)
  File "game/screens.rpy", line 277, in python
                            FileSaveName(number))
TypeError: %d format: a number is required, not str

Here's the code I have, based on what you sent me:

Code: Select all

screen load_save_slot:
    $ file_text = "% 2d. %s\n  %s" % (
                        FileSlotName(number, 4),
                        FileTime(number, empty=_("Empty Slot.")),
                        FileSaveName(number))

    add FileScreenshot(number) xpos 11 ypos 7
    text file_text xpos 80 ypos 10

screen file_picker:

    imagemap:
        ground "loadsave_ground.png"
        idle "loadsave_idle.png"
        hover "loadsave_hover.png"
        selected_idle "loadsave_selected_idle.png"
        selected_hover "loadsave_selected_hover.png"
        
        hotspot (249, 72, 48, 23) clicked FilePagePrevious()
        hotspot (309, 72, 55, 23) clicked FilePage("auto")
        hotspot (380, 72, 14, 23) clicked FilePage(1)
        hotspot (409, 72, 19, 23) clicked FilePage(2)
        hotspot (440, 72, 18, 23) clicked FilePage(3)
        hotspot (471, 72, 18, 23) clicked FilePage(4)
        hotspot (501, 72, 18, 23) clicked FilePage(5)
        hotspot (531, 72, 55, 23) clicked FilePageNext(5)
                               
        hotspot (246, 110, 342, 63) clicked FileAction(1):
            use load_save_slot(number=1)
        hotspot (246, 182, 342, 63) clicked FileAction(2):
            use load_save_slot(number=2)
        hotspot (246, 253, 342, 64) clicked FileAction(3):
            use load_save_slot(number=3)
        hotspot (246, 326, 342, 64) clicked FileAction(4):
            use load_save_slot(number=4)

            

I'm still using filepicker. Should I change that so I have all the code in the separate load/save screens as you have done?

[Alex]

About error message. In my code <$ file_text = "% 2s. %s\n%s">, but in yours <$ file_text = "% 2d. %s\n %s">. <%s> means that a string value should be used while <%d> means - data value. Just correct your code.

I'm still using filepicker. Should I change that so I have all the code in the separate load/save screens as you have done?

Mmm, look, the default "save" and "load" screens uses "file_picker" for shortening the coding, 'cause this part of script is similar for both screens.
In your case, you made two different sets of screens - the default, that accessed from main menu and your custom (with transparent bg) accessible from ingame. So you got "save"/ "load" screens and "my_save" / "my_load" screens. It would be ok to use "file_picker" in both cases, but it uses <FileAction()> function that works properly this exactly "save" and "load" screens. If you'll try to use it with your "my_save" / "my_load" screens it will only save game, but not load.
So, you'll have to change the code for default menus to make them imagemaps ("file_picker" can be used), and make the set of "my_..." screens. And in "my_save" / "my_load" screens, instead of <use file_picker>, you'll have to type the code for save slots with <FileSave()> and <FileLoad()> functions to make them work right.

[clannadman]

Thankyou for being so helpful I think I have one last query and then everything should be up and running smoothly.

I've experienced a problem with my Yes/No menus. Sometimes the actions they take don't do as they say they will and upon altering the action of the hotspots, I now get a complaint from Renpy about an str object not being callable. What is the correct action for this section to make the Yes/No hotspots do their intended task?

My code at the moment:

Code: Select all

screen yesno_prompt:
    
    modal True
    
    if message == layout.ARE_YOU_SURE:
        imagemap:
            ground "yesno_are_you_sure.png"
            idle "yesno_idle.png"
            hover "yesno_hover.png"
        
            hotspot (254, 214, 52, 32) action ("Yes")
            hotspot (338, 214, 48, 32) action ("No")
    

    if message == layout.OVERWRITE_SAVE:
        imagemap:
            ground "yesno_overwrite_save.png"
            idle "yesno_idle.png"
            hover "yesno_hover.png"
        
            hotspot (254, 214, 52, 32) action ("Yes")
            hotspot (338, 214, 48, 32) action ("No")

    if message == layout.DELETE_SAVE:
        imagemap:
            ground "yesno_delete_save.png"
            idle "yesno_idle.png"
            hover "yesno_hover.png"
        
            hotspot (254, 214, 52, 32) action ("Yes")
            hotspot (338, 214, 48, 32) action ("No")
        
    if message == layout.LOADING:
        imagemap:
            ground "yesno_loading.png"
            idle "yesno_idle.png"
            hover "yesno_hover.png"
        
            hotspot (254, 214, 52, 32) action ("Yes")
            hotspot (338, 214, 48, 32) action ("No")
        
    if message == layout.QUIT:
        imagemap:
            ground "yesno_quit.png"
            idle "yesno_idle.png"
            hover "yesno_hover.png"
        
            hotspot (254, 214, 52, 32) action ("Yes")
            hotspot (338, 214, 48, 32) action ("No")

    if message == layout.MAIN_MENU:
        imagemap:
            ground "yesno_main_menu.png"
            idle "yesno_idle.png"
            hover "yesno_hover.png"
        
            hotspot (254, 214, 52, 32) action ("Yes")
            hotspot (338, 214, 48, 32) action ("No")

I have also tried out:

Code: Select all

hotspot (254, 214, 52, 32) clicked ("Yes")
            hotspot (338, 214, 48, 32) clicked ("No")

...and:

Code: Select all

hotspot (254, 214, 52, 32) Return ("True")
            hotspot (338, 214, 48, 32) Return ("False")

[Alex]

Well, everything is in "screens.rpy", just look through the code for default "yesno_prompt" screen...))
So, instead of all <action ("Yes")> / <action ("No")>, there should be <action yes_action> / <action no_action>.

[clannadman]

Thankyou so much for your help. Sorry about being such a newbie but I didn't even realize screens.rpy existed until a few days ago ._. I'll make sure to credit you for your help

[marvelmx]

Hi, I´m having the same problem with my str not callable and I´m also a noob , so sorry if Im repeating somone or myself, I already checked the post related to this issue but I´m stillnot capable of solving it (also thanks alex for helping me so much with the other problems).

In my main menu I added an about button (just like the cookbook says ) but I´m still getting that error, the button is there but when you click it it crashes, this is my code:

Code: Select all

init: 
    # Adding about button to main menu
    $ config.main_menu.insert(3, ('About', _intra_jumps("about", "main_game_transition"), "True"))

# About box
label about:
    python hide:
        renpy.transition(config.intra_transition)
        ui.window(style=style.gm_root)
        ui.frame(ymargin=10, xmargin=10, style=style.menu_frame)
        ui.side(['t', 'c', 'r', 'b'], spacing=2)
        
        # Here you put the title of your VN
        layout.label("My visual novel", None)
        
        vp = ui.viewport(mousewheel=True)

        # This is where the text will go. You can use all the usual tags.
        ui.text(u"Informacion sobre este juego \n EL juego Fue creado....\npor motivo de.....\n ")
        ui.bar(adjustment=vp.yadjustment, style='vscrollbar')
        
        layout.button(u"Return to menu", None, clicked=ui.jumps("main_menu_screen")) 
        ui.close()
        ui.interact()
    return

And this is the tracebck : (By the way, do I use the code button in the posts for errors too?)

Code: Select all

While running game code:
TypeError: 'str' object is not callable

-- Full Traceback ------------------------------------------------------------

Full traceback:
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\execution.py", line 261, in run
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\ast.py", line 630, in execute
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\python.py", line 960, in py_exec_bytecode
  File "renpy-6.12.0-mainline/common/_layout/screen_load_save.rpym", line 17, in <module>
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\ui.py", line 236, in interact
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\core.py", line 1641, in interact
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\core.py", line 2215, in interact_core
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\layout.py", line 696, in event
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\layout.py", line 696, in event
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\layout.py", line 696, in event
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\screen.py", line 297, in event
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\layout.py", line 696, in event
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\layout.py", line 174, in event
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\layout.py", line 696, in event
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\behavior.py", line 623, in event
  File "C:\Documents and Settings\Administrador\Mis documentos\Descargas\emgine graphic adcentures\renpy-6.12.1\renpy\display\behavior.py", line 204, in run
TypeError: 'str' object is not callable

Windows-XP-5.1.2600-SP2
Ren'Py 6.12.1.1501
A Ren'Py Game 0.0

[Alex]

Hm, I've copy/pasted your code and it worked for me... Seems, that problem not in this part of code. Build the distribution of your project and attach it to the post to let people check it.