[SOLVED] How to ovelap the Namebox on the Textbox

[Colby Alighieri]

This is what I got----



---From the codes:

Code: Select all

#Message Box and Name Box

    style.say_who_window.background = Frame("ADV NameBox_v2.png", 20, 20) #Background skin
    style.say_who_window.xalign = 0.0
    style.say_who_window.yalign = 1.0
    style.say_who_window.xpos = 113 #For precise placement
    style.say_who_window.ypos = 85 #For precise placement (increasing = down)
    style.say_who_window.left_padding = 15
    style.say_who_window.top_padding = 19
    style.say_who_window.right_padding = 15
    style.say_who_window.bottom_padding = 16
    style.say_who_window.xminimum = 245
    style.say_who_window.yminimum = 36
    style.say_who_window.xfill = False
    
    style.say_label.color="#000000"
    #style.say_label.drop_shadow = [(1, 1)]
    #style.say_label.drop_shadow_color = "#cccccc"
    style.say_label.size = 20
    style.say_label.text_align = 0.5
    style.say_label.xpos = 29
    style.say_label.xalign = 0.5

All it needs to be completed is: I want the name-box to go up front so I could achieve this textbox look:



If there's a code that could put the name-box up in front instead of the back, I'd be IMMENSELY happy

If not, might as well think my way around in making this work~

[PyTom]

Go into the say screen, and re-order the two windows so that the who box comes after the what box. They're drawn from back to front, so things in the front have to be after the ones in the back.

[HigurashiKira]

Forgive me for the thread hijack, but this seemed to have been relevant to my problem. I did as Tom commented, but this happened:

Code: Select all

else:

        # The two window variant.
        vbox:
            style "say_two_window_vbox"

            
                        
            window:
                id "window"

                has vbox:
                    style "say_vbox"

                text what id "what"
            if who:            
                window:
                    style "say_who_window"

                    text who:
                        id "who" 

[nyaatrap]

xalign and yalign can adjust it. like

Code: Select all

    if who:
        window:
            xalign 0.1
            yalign 0.8

0.1 and 0.8 is sample parameters though.

[Colby Alighieri]

xalign and yalign can adjust it. like

Code: Select all

    if who:
        window:
            xalign 0.1
            yalign 0.8

0.1 and 0.8 is sample parameters though.

The xalign helped in the positioning, so thanks! But the problem now lies with the yalign. No matter how I changed the values, the namebox doesn't move and stays where it is like a lemon.



This is how I coded it:

Code: Select all

# The two window variant.
        vbox:
            style "say_two_window_vbox"

            if who:            
                window:
                    xalign 0.21
                    yalign 10
                    
                    style "say_who_window"

                    text who:
                        id "who"
                        
            window:
                id "window"

                has vbox:
                    style "say_vbox"

                text what id "what"

I switched back to the default order of the who and what boxes for nyaatrap's solution since combining Pytom's instructions and nyaatrap's created another problem. Forgive my use of words...

Hey there HigurashiKira. Glad we have the same problem

[nyaatrap]

[/deleted wrong code]

[PyTom]

You probably want to turn that vbox into a fixed, and just position everything using xpos/ypos.

[nyaatrap]

You probably want to turn that vbox into a fixed, and just position everything using xpos/ypos.

Ahhh.. I forgot the existence of that vbox *ashamed

[Colby Alighieri]

You probably want to turn that vbox into a fixed, and just position everything using xpos/ypos.

Ahhh.. I forgot the existence of that vbox *ashamed

Would you mind reposting that code you deleted up there? I didn't have the chance to read it. I might understand something back there because I don't know what's with the "fixed" and the vbox.

[nyaatrap]

Please forget about that code *embarrassed

Code: Select all

# The two window variant.
        vbox:
            style "say_two_window_vbox"

This vbox was the reason yalign didin't work, because a vbox places following windows vertically.
If you change it to a fixed, you can position windows freely.

Code: Select all

# The two window variant.
        fixed:
            style "say_two_window_vbox"

[HigurashiKira]

Again, pardon the hijack, but I've done all the reccomendations on this thread, and still I get this:

Code: Select all

        # The two window variant.
        fixed:
            style "say_two_window_vbox"

            
                        
            window:
                id "window"

                has vbox:
                    style "say_vbox"

                text what id "what"
           
            if who:            
                window:
                    xalign 0.01
                    yalign 0.15
                    style "say_who_window"

                    text who:
                        id "who" 

Code: Select all

    style.say_who_window.background = Frame("namebox.png", 0, 0)
    style.say_who_window.left_margin = 0
    style.say_who_window.right_margin = 0
    style.say_who_window.left_padding = 0
    style.say_who_window.right_padding = 0
    style.say_who_window.xminimum = 0
    style.say_who_window.ypos = 0

Help?

[Colby Alighieri]

Please forget about that code *embarrassed

Code: Select all

# The two window variant.
        vbox:
            style "say_two_window_vbox"

This vbox was the reason yalign didin't work, because a vbox places following windows vertically.
If you change it to a fixed, you can position windows freely.

Code: Select all

# The two window variant.
        fixed:
            style "say_two_window_vbox"

I followed your instructions but the namebox is still stuck like a lemon.



Here's what I have if it helps.

Code: Select all

 # The two window variant.
        fixed:
            style "say_two_window_vbox"
            
            if who:            
                window:
                    xalign 0.21               
                    yalign 0.29
                    style "say_who_window"

                    text who:
                        id "who"
                        
            window:
                id "window"

                has vbox:
                    style "say_vbox"

                text what id "what"

And here, just in case the problem lies here.

Code: Select all

#Message Box and Name Box
    style.say_who_window.background = Frame("ADV NameBox_v2.png", 20, 20) #Background skin
    style.say_who_window.xalign = 0.0
    style.say_who_window.yalign = 1.0
    style.say_who_window.xpos = 114 #For precise placement
    style.say_who_window.ypos = 89 #For precise placement (increasing = down)
    style.say_who_window.left_padding = 9
    style.say_who_window.top_padding = 9
    style.say_who_window.right_padding = 9
    style.say_who_window.bottom_padding = 9
    style.say_who_window.xminimum = 245
    style.say_who_window.yminimum = 36
    style.say_who_window.xfill = False
    

And HigurashiKira, thread hijacking is welcome for me as long as the problem is related

[nyaatrap]

I should have posted full code >_<
Use ypos instead of yalign. Here is a sample code

Code: Select all

        # The two window variant.
        fixed:
            style "say_two_window_vbox"
            
            window:
                ypos 200
                id "window"

                has vbox:
                    style "say_vbox"

                text what id "what"

            if who:
                window:
                    xpos 100
                    ypos -50
                    style "say_who_window"

                    text who:
                        id "who"

and I got this

[edit:]
Also, following codes are no more needed. You can delete them.

Code: Select all

    style.say_who_window.xalign = 0.0
    style.say_who_window.yalign = 1.0
    style.say_who_window.xpos = 114 #For precise placement
    style.say_who_window.ypos = 89 #For precise placement (increasing = down)

[HigurashiKira]

And that worked (For me at least). Thank you~

[Colby Alighieri]

I should have posted full code >_<
Use ypos instead of yalign. Here is a sample code

Code: Select all

        # The two window variant.
        fixed:
            style "say_two_window_vbox"
            
            window:
                ypos 200
                id "window"

                has vbox:
                    style "say_vbox"

                text what id "what"

            if who:
                window:
                    xpos 100
                    ypos -50
                    style "say_who_window"

                    text who:
                        id "who"

and I got this

[edit:]
Also, following codes are no more needed. You can delete them.

Code: Select all

    style.say_who_window.xalign = 0.0
    style.say_who_window.yalign = 1.0
    style.say_who_window.xpos = 114 #For precise placement
    style.say_who_window.ypos = 89 #For precise placement (increasing = down)

8D Ohmigosh! It works now!



Thank you for a thousand suns! Really! Thank you for the patience and coding knowledge you have imparted on us!

THANKS nyaatrap and PyTom FOR THEIR SOLUTIONS. NOW I COULD SAY--

!!! CASE CLOSED !!!