Changing appearance of previously-made choices

[Yako]

I am working on an Ace Attorney-style investigation/mystery game. Currently, I'm refining the way questioning other characters works. It's implemented with the default choice menus and that's all great; HOWEVER.

I would like to have it so that, when you're at the menu, choices that have already been explored have a different look to them than choices that have not yet been selected. The "chosen" boolean in the choice screen was close to what I want, but it's a persistent variable and I need it to operate on a per-playthrough level. Is there a way to do this at all?

If you need any code from me, or need clarification on what I'm looking for, please tell me. I'm new to asking questions so I'm not sure how to go about it. Thanks for your time.

[apricotorange]

Put the following somewhere in your project, and the "chosen" boolean will work the way you want:

Code: Select all

init python:
    # Track which choices have been chosen
    chosen_choice_tracker = None

    # Action for menu which tracks the chosen choice.
    class NonPersistentChoice(Action):
        def __init__(self, label, value, location):
            self.label = label
            self.value = value
            self.location = location

        def __call__(self):
            chosen_choice_tracker[(self.location, self.label)] = True
            return self.value

    def menu(items):
        global chosen_choice_tracker
        if not chosen_choice_tracker:
            chosen_choice_tracker = {}
        # Get the name of the current statement
        # (This is not a public API, but I couldn't find an equivalent.)
        location = renpy.game.context().current
        # Build the list of items in the form the screen wants
        item_actions = [ ]
        for (label, value) in items:
            action = NonPersistentChoice(label, value, location)
            item_actions.append((label, action, (location, label) in chosen_choice_tracker))
        # Display the screen
        return renpy.call_screen("choice", items=item_actions)

[Yako]

That is working exactly right. Thank you so much!