Looking for a solution for audio playback

[ReAnimator]

Hello,
I am experiencing technical problem on sound.
Say, I have this monster. It's growling (loop footage). Then I want him to speak.
Once it finished his sentence, I want its growling back without getting back to the beginning.
Like this. "Grrrr 'Ha-ha-ha' rrrrr --- Grrrrrrrrr"
I have no idea how to do this. Can anyone give me a light?

[PyTom]

You could do something like:

Code: Select all

play sound "growl.ogg" loop
"..."

$ renpy.music.set_volume(0.0, .25, channel='sound')
voice "hahaha.ogg"
monster "Ha-ha-ha"

$ renpy.music.set_volume(1.0, .25, channel='sound')
"..."

http://www.renpy.org/doc/html/audio.htm ... set_volume

[ReAnimator]

Ahh! Volume! I've never thought about that. Big thanks, Pytom.
Another question.
Is it possible to get back to growling right after the sentence is finished without touching anything?
I mean, in this case it won't come back until you click the button, right?

[ReAnimator]

Hi,
I'm still looking for a solution for this.
Currently I have to manually mute the voice effect every time he speaks.
I don't think this is an efficient way to do this.
Is there any ways to 'keep watching if the character speaks, if not, the voice effect appears' which I think a lot better.

[SinnyROM]

Maybe you can use the character callback property for this? http://www.renpy.org/doc/html/character_callbacks.html
This example can be modified to mute/unmute in addition to playing a sound: http://lemmasoft.renai.us/forums/viewto ... 263#p73263

[ReAnimator]

Hey, SinnyROM! Thanks for your help!
It works great. Much much better than manually placing codes.
It's perfect if the voice effect continues after the dialogue without clicking though.
I also wonder

init python:
def callback(event, **kwargs):

what's this **kwargs thingy???

[SundownKid]

Hey, SinnyROM! Thanks for your help!
It works great. Much much better than manually placing codes.
It's perfect if the voice effect continues after the dialogue without clicking though.
I also wonder

init python:
def callback(event, **kwargs):

what's this **kwargs thingy???

"args" means arguments. It means whatever additional arguments you want to add there.

[ReAnimator]

Hey, SundownKid!
I am pretty much novice so I don't understand what that means but if I take this out from code Ren'py returns error. So this additional arguments must be necessary for some reason? Why's the name **kwargs?? I can change it to **abc and it still works. What's the point of having this in the code?

[SinnyROM]

SundownKid mentioned args is arguments; the kw is for keywords. So **kwargs takes in a certain type of argument with keys, i.e. a dictionary. The name is a convention, so as long as you keep ** in the parameters it'll be fine. Here's a page with an explanation and some examples: http://markmiyashita.com/blog/python-args-and-kwargs/

I'm not sure why it wouldn't work without **kwargs - maybe the callback function requires it somehow. I don't see it but someone else with a clearer mind might!

[trooper6]

**kwargs must be in the code.

What it means is that you can add in additional keyword arguments to your callback, if you like. But if you don't need additional information passed to your callback, you can ignore it--but don't delete it.

How would you use a keyword arg? Well there are many ways depending on your imagination. But here is one example.

Let's say you want clicks to play when your characters are speaking using slow text...but not when they are not speaking. You could make a callback like so:

Code: Select all

init -1 python:
    renpy.music.register_channel("Chan1", mixer= "sfx", loop=True)
            
    def clicks(event, **kwargs):
        if event == "show" or event == "begin":
            renpy.music.play("click.wav", channel="Chan1")     
        if event == "slow_done" or event == "end":
            renpy.music.stop(channel="Chan1")

And then you give your callback to a character and you are good to go:

Code: Select all

define e = Character('Eileen', color="#c8ffc8", what_slow_cps=20, what_slow_abortable=False, callback=clicks)

What if you have two characters and you want a different click sound to happen for each one? You could make two different callbacks:

Code: Select all

init -1 python:
    renpy.music.register_channel("Chan1", mixer= "sfx", loop=True)
            
    def clicks1(event, **kwargs):
        if event == "show" or event == "begin":
            renpy.music.play("high_click.wav", channel="Chan1")     
        if event == "slow_done" or event == "end":
            renpy.music.stop(channel="Chan1")

    def clicks2(event, **kwargs):
        if event == "show" or event == "begin":
            renpy.music.play("low_click.wav", channel="Chan1")     
        if event == "slow_done" or event == "end":
            renpy.music.stop(channel="Chan1")

And then define your two characters:

Code: Select all

define e = Character('Eileen', color="#c8ffc8", what_slow_cps=20, what_slow_abortable=False, callback=clicks1)
define f = Character('Faye', color="#c8ffc8", what_slow_cps=20, what_slow_abortable=False, callback=clicks2)

That would work...but you are repeating code, and whenever you start repeating code there is probably a more efficient way to do what you want to do. What happens if instead of just two different clicks...you had 10? Then you'd have to make ten different callbacks? Nope, you can just have one callback and use a keyword arg. That would look like this (we are going to add a keyword argument called "char" that tells us which character is speaking and then we will decide which click sound to play based on that):

Code: Select all

init -1 python:
    renpy.music.register_channel("Chan1", mixer= "sfx", loop=True)
            
    def clicks(event, char=1, **kwargs):
        if event == "show" or event == "begin":
            if char == 1:
                renpy.music.play("high_click.wav", channel="Chan1")
            if char == 2:  
                renpy.music.play("low_click.wav", channel="Chan1")
            if char == 3:
                renpy.music.play("med_click.wav", channel="Chan1")
        if event == "slow_done" or event == "end":
            renpy.music.stop(channel="Chan1")

Then you make your characters, and include a callback keyword...which in this case looks like 'cb_char':

Code: Select all

define e = Character('Eileen', color="#c8ffc8", what_slow_cps=20, what_slow_abortable=False, callback=clicks, cb_char=1)
define f = Character('Faye', color="#c8ffc8", what_slow_cps=20, what_slow_abortable=False, callback=clicks, cb_char=2)
define r = Character('Roger', color="#c8ffc8", what_slow_cps=20, what_slow_abortable=False, callback=clicks, cb_char=3)

[ReAnimator]

Thanks, SinnyROM and trooper6!
Your explanation is very helpful but clearly beyond my knowledge.
I can somehow understand what you wrote but it's impossible to get on my own.
I'll leave that **kwarg.
Thank you, both. I really appreciate!

Code: Select all

init -1 python:
    renpy.music.register_channel("Chan1", mixer= "sfx", loop=True)
           
    def clicks(event, char=1, **kwargs):
        if event == "show" or event == "begin":
            if char == 1:
                renpy.music.play("high_click.wav", channel="Chan1")
            if char == 2: 
                renpy.music.play("low_click.wav", channel="Chan1")
            if char == 3:
                renpy.music.play("med_click.wav", channel="Chan1")
        if event == "slow_done" or event == "end":
            renpy.music.stop(channel="Chan1")

In the last example, I have to replace char to cb_char, no?

[trooper6]

In the last example, I have to replace char to cb_char, no?

Nope.

When you make your callback you just give that callback a name...like "char."

so:

Code: Select all

def clicks(event, char=1, **kwargs):

But when you are making a character...

Code: Select all

define e = Character('Eileen', color="#c8ffc8", what_slow_cps=20, what_slow_abortable=False, callback=clicks, cb_char=1)

What you have here is the character Eileen. And you have defined here with a bunch of keyword arguments that belong to her: color, what_slow_cps, what_slow_abortable, callback.
If you put char=1 in her definition, renpy would think that char is a keyword argument that belongs to eileen. But it is a keyword argument that belongs to the callback. The way you let the program know it is the callback's keyword and not Eileen's keyword is by adding the prefix "cb_" to the keyword. In this case you end up with, cb_char.

[ReAnimator]

The way you let the program know it is the callback's keyword and not Eileen's keyword is by adding the prefix "cb_" to the keyword. In this case you end up with, cb_char.

Thanks again but... how does the one know this?? Like adding prefix "cb_"... It must be strictly "cb_", right? Oh my... I'm getting nervous... I will never get this right...

[trooper6]

The way you let the program know it is the callback's keyword and not Eileen's keyword is by adding the prefix "cb_" to the keyword. In this case you end up with, cb_char.

Thanks again but... how does the one know this?? Like adding prefix "cb_"... It must be strictly "cb_", right? Oh my... I'm getting nervous... I will never get this right...

Most things are well documented. The cb_ prefix thing is not well documented. It showed up in a changelog post for 6.2.0: http://lemmasoft.renai.us/forums/viewto ... 873#p27873

But I just found out about it by not getting it to work and asking on the forums and getting someone to explain it to me. As far as I know, however, callback is the only one that takes a prefix for its keyword args in the character definition. So...you know that one and that should be it.