Showing a screen with a transition

[cbx33]

Ok, so off the back of the last post, I have been advised to use a screen instead of calling my UI elements with python code, which is fine, however I can only get the Dissolve transition to work when showing the scree and can someone tell me why I have to use such rediculous x/ypos values when using 1280x720 res screen.....

Code: Select all

screen show_phone:
    if show_p:
        window:
            background 'extras/phone.png'
            top_padding 80
            left_padding 65
            xpos 1530
            ypos 500
            #,xpos=1530, ypos=547, top_padding=80, left_padding=65)
            vbox:
                text(phone_message)
                hbox:
                    textbutton _("Close") action Hide('show_phone', transition=dissolve)

And if I try to invoke with a

Code: Select all

show screen

like so....

Code: Select all

    $ phone_message = "You got mail"
    $ show_p = True
    show screen show_phone
    with dissolve

it works, but any other transition doesn't seem to. In particular I wanted to moveinbottom.

Any takers?

[Arowana]

Hmm, I usually show screens with "transforms" rather than "transitions." Not sure why transitions don't work, quite honestly, but if you want a "moveinbottom" type effect, you can define an ATL transform like:

Code: Select all

init:
    transform moveup:
       ypos 1.0 # start low
       ease 0.5 ypos 0.5 # move up in 0.5 seconds

You can also specify specific animations for showing vs. hiding the screen using "on show" and "on hide" - example.

Then for your phone screen, add "at moveup" to your screen window.

Code: Select all

screen show_phone:
    if show_p:
        window:
            at moveup #<---------------------------------------specifies transform to use
            background 'extras/phone.png'
            top_padding 80
            left_padding 65
            xpos 1530
            ypos 500
            #,xpos=1530, ypos=547, top_padding=80, left_padding=65)
            vbox:
                text(phone_message)
                hbox:
                    textbutton _("Close") action Hide('show_phone', transition=dissolve)

Lol, not sure why your positions are so large - is your image weirdly sized/has a lot of empty space around it?

[cbx33]

That worked awesomely Arowana
I guess I was getting confused between transitions and transforms and didn't really know which was the right one to use. It "should" have worked with the transition, but works awesomely with the transform.

The image is small. 334x444px
Is it possibly because I didn't specify a width for the window? I dunno, but it's working well now. Thank you

[Update] I found out how to fix the odd dimensions. I had not set an xanchor/yanchor. After setting those to 0, it performed a lot more predictably.

[cbx33]

OK, another small problem. I wanted to make some buttons to scroll through a text message on the phone

Code: Select all

    $ phone_message = "You got mail\nand it's cool\nthat we can\nscroll through\na message\nYou got mail\nand it's cool\nthat we can\nscroll through\na message"
    $ show_p = True
    $ phone_offset = 0
    show screen show_phone

And the screen code is here, note I have some debug messages

Code: Select all

screen show_phone:
    if show_p:
        window:
            $ print " " + str(phone_offset)
            $ m_len = phone_message.split("\n")
            if phone_offset < 0: 
                $ print "I'm low"
                $ phone_offset = 0
            elif phone_offset > len(m_len)-5:
                $ print "I'm high"
                $ phone_offset = len(m_len)-5

            $ m_dict = phone_message.split("\n")[phone_offset:phone_offset+5]

            at phone_trans
            background 'extras/phone.png'
            top_padding 80
            left_padding 65

            vbox:
                text("\n".join(m_dict))
                text(str(phone_offset))
                hbox:
                    textbutton _("Down") action SetVariable('phone_offset', phone_offset + 1)
                    textbutton _("Close") action Hide('show_phone')
                    textbutton _("Up") action SetVariable('phone_offset', phone_offset - 1)

Now the buttons work fine, until I hit one of the limits defined in the IF statement. Can anyone give me a hint as to how to fix this?

[Levrex]

Try adding "else" too?

[cbx33]

I'll give that a go

[cbx33]

Tried that, still doesn't work. Interestingly I'm using a default style for the UI elements and the buttons seemed to glow, ie the text colour gets brighter and stays that way....like it's hitting some kind of loop condition. Interestingly also, when I added an else that did

Code: Select all

$ phone_offset = phone_offset

The buttons didn't work at all. It is almost like those conditions are being evaluated constantly and the inc/dec of the buttons never gets used. Without the else, the buttons do work up until their limits are reached.

[Arowana]

Oh, that's an cool way to scroll text! I've usually just seen people use viewports, so your method is pretty interesting.

Not entirely sure, but my hunch for why this is not working is that "if" statements checking for out-of-bounds values of "phone_offset" are only run once, when the screen is initially called. Since "phone_offset" is 0 initially, it just passes through without doing anything. Then when the "phone_offset" values get out-of-bounds, you get problems.

One way around this is to make the button actions conditional, so they won't go out-of-bounds in the first place. So maybe something like:

Code: Select all

textbutton _("Down") action If( (phone_offset+1 > len(m_len)-5), SetVariable('phone_offset', len(m_len)-5), SetVariable('phone_offset', phone_offset + 1))

textbutton _("Up") action If( (phone_offset-1 < 0), SetVariable('phone_offset', 0), SetVariable('phone_offset', phone_offset - 1))     

An alternative way could be to hide and reshow the screen whenever you click a button, so the "if" statements will be rechecked each time. Since your screen has an entrance animation, however, you might have to define an alternate version without the animation (else the screen will "pop up" each time it is reshown).

[cbx33]

That worked beautifully
Thanks