Character image selection?

[lemonokashi]

Sorry if this is a stupid question, but I wanted the option of choosing a male or female protagonist that will define character images without writing an if statement every time I need to show that character? For example is there any statement I could use to define a specific image command as using a different image depending on a user's choice at the beginning of the game?

[Suika]

You could save the character image as a variable, and just access the variable whenever you need to display the character.

More specifically:
-User selects a character image (userSelection)
-Store userSelection in a variable (playerImage)
-Display playerImage whenever the player is to be shown.

[Tsapas]

I believe you are referring to side images? You can try this:

Code: Select all

$ pov = Character('Player', color="#F8BA87",show_side=ConditionSwitch("povGender == Male", "pov_male.png","povGender == Female", "pov_female.png"))

[OokamiKasumi]

...I wanted the option of choosing a male or female protagonist that will define character images without writing an if statement every time I need to show that character? For example is there any statement I could use to define a specific image command as using a different image depending on a user's choice at the beginning of the game?

This is exactly what I did in my most recent game "Trap!"
-- I accomplished this by way of a ConditionSwitch in the image definitions.

First, you'll need to define ALL versions of your PC images with ConditionSwitch.
-- I only had 3 versions of each image: Neutral, Annoyed, and Concerned in Left & Right, making 6 total images in both male & female.

Code: Select all

init:
    image pc = "ch/male/mConR.png"
# ----------------------------------------------------
    image pc neuR = ConditionSwitch(
        "gender == 'female' ", Image ("ch/fem/fNeuR.png"),
        "gender == 'male' ", Image ("ch/male/mNeuR.png"),
        "True", Image ("ch/male/mNeuR.png"),
        )

    image pc neuL = ConditionSwitch(
        "gender == 'female' ", Image ("ch/fem/fNeuL.png"),
        "gender == 'male' ", Image ("ch/male/mNeuL.png"),
        "True", Image ("ch/male/mNeuL.png"),
        )

I created a whole separate .rpy page just for these definitions alone called "xLiveComposite.rpy".

Next, in script.rpy define your character so that it can be named.

Code: Select all

init:
    $ e = DynamicCharacter("pc_name", 
        color="#ffffcc",
        outlines = [(1, "#333300", 0, 0)],
        drop_shadow = (2, 2,),
        what_prefix="\"",
        what_suffix="\"",
        show_two_window = True,
        ctc="ctc_blink",
        ctc_position="fixed",)

    $ e_side = DynamicCharacter("pc_name", 
        color="#ffffcc",
        outlines = [(1, "#333300", 0, 0)],
        drop_shadow = (2, 2,),
        show_side_image=ConditionSwitch(
            "gender == 'female' ", "ch/fem/f_side.png",
            "gender == 'male' ", "ch/male/m_side.png",
            xalign=0.0, yalign=1.0),
        what_prefix="\"",
        what_suffix="\"",
        show_two_window = True,
        ctc="ctc_blink",
        ctc_position="fixed",)

Add the variable flags that will code in the player's gender selection and name:

Code: Select all

# -----------------------------------------
label start:
    $ pc = " "
    $ gender = " " 

Next, add the code that allows the player to choose their Gender and Name:

Code: Select all

#################################################
    scene bg_02
    show gal at right
    show guy at left 
    with fade
    
    menu:
        "Would you like a Male Lead character?":
            $ gender = 'male'
            hide gal with dissolve
            show guy at center with move

        "Or a Female Lead character?":
            $ gender = 'female'
            hide guy with dissolve
            show gal at center with move
            
label name:
    $ pc_name = renpy.input("What would you like to name your character? \n{i}{color=#cccc99} -- Backspace to erase the current name. When you're done, hit Enter.{/color}{/i}\n", "Chris", length=15)
    $ pc_name = pc_name.strip()
    
    scene black with fade    

Your game officially starts after this point.

Done this way, you can simply show, hide, and transition your character image just like any other image -- without the need of any extra flags.

Code: Select all

    show pc neuL at right with moveinright

I hope that helps.

[xela]

Sorry if this is a stupid question, but I wanted the option of choosing a male or female protagonist that will define character images without writing an if statement every time I need to show that character? For example is there any statement I could use to define a specific image command as using a different image depending on a user's choice at the beginning of the game?

There are to many ways of doing this... best way is to sort all of the images in two folders (male/female), bulkload them into the game and allow player to pic one.

[lemonokashi]

That is so helpful! Thank you very much!