Transparent image over an imagemap

[Visiden]

I'm starting to wonder if it's even possible. I'm trying to get a transparent image to show up over my main menus image map so I can use a transform on it. Can anyone help me out?

[trooper6]

Could you explain this a bit more?

You have a transparent image that shows nothing. And then you want to transform this transparent image? But no one can see what you did?

Anyway, what I'd say is, just put your image on a screen and then show the screen wherever you want.

[xavimat]

Maybe imagebuttons are more versatile for your needs, instead of an imagemap

[Visiden]

Could you explain this a bit more?

You have a transparent image that shows nothing. And then you want to transform this transparent image? But no one can see what you did?

Anyway, what I'd say is, just put your image on a screen and then show the screen wherever you want.

Sorry, I can see why that would be a little confusing. What I mean to ask is...

I have set up an imagemap on my games main menu. I want to put an image over it that will rotate slowly. I'm really not sure why I thought the image having transparency was relevant, lack of sleep can do strange things.

[trooper6]

Ah!

xavimat is correct, you want imagebuttons over an image rather than an imagemap.
Here is the tutorial on imagebuttons: http://lemmasoft.renai.us/forums/viewto ... 51&t=22565

[Visiden]

Ah!

xavimat is correct, you want imagebuttons over an image rather than an imagemap.
Here is the tutorial on imagebuttons: http://lemmasoft.renai.us/forums/viewto ... 51&t=22565

I'll look into imagebuttons, but i'm not sure I really need them. To clarify further, the rotating element isn't a button, and is only there for aesthetic. Is it just not possible to layer it over the imagemap? I feel like this would be easier than converting the menu to imagebuttons...

[trooper6]

Sure. Do what I said in my first post.

Put the image on a screen. And give it the rotating transform. Then show the screen, placing it where you want so it is wherever you want.

[trooper6]

Here is some code that I made as an experiment. The one think I couldn't get it to do is rotate forever. Perhaps someone else knows how to do that?

Anyway:

Here is the code I made in the script.rpy.

Code: Select all

screen gear() align (0.5, 0.5):
    add "gear.png":
        xalign 0.5 yalign 0.5
        xanchor 0.5 yanchor 0.5
        at alwaysrotate
            
transform alwaysrotate:
    rotate_pad True
    linear 3.0 rotate 360
    repeat
  
# The game starts here.
label start:
    "This is just a game that is being tested."

And this is how I modified the screens.ry

Code: Select all

##############################################################################
# Main Menu
#
# Screen that's used to display the main menu, when Ren'Py first starts
# http://www.renpy.org/doc/html/screen_special.html#main-menu

screen main_menu():

    # This ensures that any other menu screen is replaced.
    tag menu

    # The background of the main menu.
    window:
        style "mm_root"

    # The main menu buttons.
    frame:
        style_group "mm"
        xalign .98
        yalign .98

        has vbox

        textbutton _("Start Game") action Start()
        textbutton _("Load Game") action ShowMenu("load")
        textbutton _("Preferences") action ShowMenu("preferences")
        textbutton _("Help") action Help()
        textbutton _("Quit") action Quit(confirm=False)

    use gear()
init -2:

    # Make all the main menu buttons be the same size.
    style mm_button:
        size_group "mm"

[Visiden]

Thank you for your replies! Okay, sorry for the late reply, but that seems to have helped... slightly. I've got the image showing over the imagemap, so at least that's something. However I can't seem to get it to rotate at all.

Code: Select all

screen mm_flair_rotate() align (0.5, 0.5):
    add "menus/menu_flair.png"
    xalign 0.5 yalign 0.5
    xanchor 0.5 yanchor 0.5
    at mm_rotate

    
transform mm_rotate:
    subpixel True
    rotate_pad True
    linear 1.0 rotate 360
    repeat

I've tried variations on this, and none of them seem to really make a difference. Still stuck. At least getting it to show is progress.

[trooper6]

I noticed in my code after the add image line of code, I put a colon and then indented the next three lines (with the anchor, alignment, and transform). You don't have that colon and indentation. Have you tried it with the colon and indentation?

[Visiden]

I noticed in my code after the add image line of code, I put a colon and then indented the next three lines (with the anchor, alignment, and transform). You don't have that colon and indentation. Have you tried it with the colon and indentation?

Yes, I did try this, but when I tried to launch the project I received error messages. I forget what exactly they were but something along the lines of not expecting a block after that statement.

Edit: I fixed it, but it's only rotating once, as you said. Also, I suppose I should have been more clear for my purposes.

This is making it orbit the center of the screen, rather than rotate. I guess I should have said spin. Hm. Sorry for any confusion. I'll try to tinker with it some more.

This is more progress than I was able to make on my own.

Post Edit Edit: I figured out the problem with it orbiting, it's the image resolution. Maybe. I think I need to crop it and give it a point (the center of the image) to rotate around, but I'm not sure how to position the image to where it needs to be in order to do that.

[trooper6]

The ATL section in the tutorial game has images that spiral, checking that out should give you the code that you need.

[xavimat]

The transform needs a point to start and to end. The always rotating effect can be achieved this way:

Code: Select all

transform mm_rotate:
    subpixel True
    rotate_pad True
    rotate 0   
    linear 1.0 rotate 360
    repeat

That means:
- The rotate 0 is the initial point, the rotate 360 is the final point, a second later.
- The repeat statement forces the image to be, again, at rotate 0. You can't see that, because rotate 0 and rotate 360 are the same position, but internally are not the same number.
- Without the "rotate 0" line, the repetition of "linear 1.0 rotate 360" tells the transform to rotate to 360 an image that is already rotated, doing nothing.

[Visiden]

The transform needs a point to start and to end. The always rotating effect can be achieved this way:

Code: Select all

transform mm_rotate:
    subpixel True
    rotate_pad True
    rotate 0   
    linear 1.0 rotate 360
    repeat

That means:
- The rotate 0 is the initial point, the rotate 360 is the final point, a second later.
- The repeat statement forces the image to be, again, at rotate 0. You can't see that, because rotate 0 and rotate 360 are the same position, but internally are not the same number.
- Without the "rotate 0" line, the repetition of "linear 1.0 rotate 360" tells the transform to rotate to 360 an image that is already rotated, doing nothing.

Thank you so much! Both of you. I've got it working now! This post helped a lot.