[Solved]Ingame menu/choices transitions?

[somein96]

Hi I was wondering if it's possible to assign a transition to choice menus, and if so how would I go about doing that?

[philat]

You can assign an ATL transform to the choice screen using on show / on hide. http://www.renpy.org/doc/html/atl.html#on-statement

Or you can apply the transform to the buttons, I guess, which are drawn in a for loop so you'd only need to apply it once.

[Donmai]

There are two approaches: common transitions or ATL transforms. You can apply a transition to a menu this way:

Code: Select all

    menu:
        with dissolve #you can use any other transition instead of dissolve
        f "What color do you prefer?"
        "I prefer red.":
            jump red
        "I prefer blue.":
            jump blue

To use an ATL transform, you must make a little edit on the choice screen. You will find it on your screens.rpy. Find these lines:

Code: Select all

##############################################################################
# Choice
#
# Screen that's used to display in-game menus.
# http://www.renpy.org/doc/html/screen_special.html#choice

screen choice:

    window:
        style "menu_window"

and insert your transform name after the window statement:

Code: Select all

##############################################################################
# Choice
#
# Screen that's used to display in-game menus.
# http://www.renpy.org/doc/html/screen_special.html#choice

screen choice:

    window:
        at fromRight 
        style "menu_window"

Define your transform anywhere (Personally, I like to have a separate script for my transforms):

Code: Select all

    transform fromRight:
        subpixel True
        alpha 0.0 xalign 1.0 xanchor 0.0
        parallel:
            easein 1.0 alpha 1.0
        parallel:
            easein 1.0 xalign 0.5
        on hide:            
            alpha 1 zoom 1 xanchor 0.5 yanchor 0.5
            block:
                linear 0.1 zoom 1.1
                linear 0.5 zoom 0

Using this second method all your in-game menus will use the same transform.

[somein96]

Thank you very much! These were exactly what I was looking for =D

[Nova Alamak]

Thanks for the info! This was really well-answered. I was wondering if there's a similar way to also use a transition after the choice is made? Say I had my menu slide in from the left with the moveinleft transform; where would I place a moveoutleft transition to slide it on out afterward?

EDIT: Never mind! I tried the ATL method instead and my question is now invalid!

[trismegistus]

Thanks for this. Relatedly, I was wondering if it's possible to make each menu option transition in one at a time. I tried moving the "at fromRight" statement into the for loop:

Code: Select all

            for caption, action, chosen in items:

                if action:

                    button:
                        at fromRight
                        action action
                        style "menu_choice_button"

                        text caption style "menu_choice"

                else:
                    text caption style "menu_caption"

...but they all still seem to slide in at the same time. I'm guessing it's because there's nothing making it delay each subsequent option. Can I make it delay playing the transition by a slightly longer amount for each button?

[Alex]

This will make them appear one after another

Code: Select all

transform my_tr(t=0):
    xpos 1.2 xanchor 0.0
    t*0.5
    linear 1.0 xalign 0.5

    
screen choice(items):

    window:
        style "menu_window"
        xalign 0.5
        yalign 0.5

        vbox:
            style "menu"
            spacing 2

            for i, (caption, action, chosen) in enumerate(items):

                if action:
                    button:
                        action action
                        style "menu_choice_button"

                        text caption style "menu_choice"
                        at my_tr(t=i)

                else:
                    text caption style "menu_caption" at my_tr(t=i)

https://docs.python.org/2/library/funct ... #enumerate

[trismegistus]

Thanks, that's just what I need. The only thing that confuses me is the line that's just "t*0.5" with no statement or anything. Does Ren'py just treat a number on its own line as "wait for this many seconds"?

[Alex]

Looks like (https://www.renpy.org/doc/html/atl.html ... -statement).