Adding delay between displayables in a screen

[RVNSN]

How do you make a delay between displayables in a screen? I'm attempting to add an animation (ships_log_opening_anim_1) for my stats screen - it's a book opening - and delay any screen actions that come after it. As it is, the text buttons that come after load at the same time (obviously).

Code: Select all

screen statpage():


    fixed:
        imagebutton auto "gui/clear_overlay_%s.png":
            xalign 0.5
            yalign 0.5
            action NullAction()

        add "ships_log_opening_anim_1" #(delay = 5)

#        imagebutton auto "gui/ships_log_inside_%s.png":
#            xalign 0.5
#            yalign 0.5
#            action NullAction()
#        textbutton _("[name]") text_color "#000000" text_hover_color "#980002" xpos 550 ypos 150 action ui.callsinnewcontext ("call_panstat")



    vbox:
        textbutton "[name]":
            text_color "#000000"
            text_hover_color "#980002"
            xpos 550 ypos 150
            action ui.callsinnewcontext ("call_panstat")

[nananame]

While you could use a timer I don't recommend that as it seems timer's are quite intensive.

Why not split the two? either have it on two screens, so on one screen you have the animation and then the other has buttons and you call it like:
show screen animation
pause 5#duration of animation
hide screen animation #this is so that if a player clicks he can skip the animation
call screen mainthingy

Or you can even avoid the screen for the animation and simply use an image but the same method as above:
show ships_log_opening_anim_1
pause 5
hide ships_log_opening_anim_1
call screen mainthingy

[Alex]

You could make a variable to check if buttons should be shown or not, and a timer that will set the proper value to this variable.

Try

Code: Select all

screen test_scr():
    default flag_var = False # default value of screen variable

    add 'ships_log_opening_anim_1' # show your animation

    if not flag_var:
        timer 5.0 action SetScreenVariable("flag_var", True) repeat False

    else: # show some buttons
        vbox:
            textbutton "Test!" action NullAction()

https://www.renpy.org/doc/html/screens.html#timer
https://www.renpy.org/doc/html/screen_a ... enVariable

[Remix]

... or put the button vbox at a transform that waits 5.0 seconds before dissolving them in

Code: Select all

transform vbox_show:
    alpha 0.0
    on show:
        pause 5.0
        linear 1.0 alpha 1.0
        
# screen ....
    
    vbox at vbox_show:
        # the buttons

[RVNSN]

You could make a variable to check if buttons should be shown or not, and a timer that will set the proper value to this variable.

Try

Code: Select all

screen test_scr():
    default flag_var = False # default value of screen variable

    add 'ships_log_opening_anim_1' # show your animation

    if not flag_var:
        timer 5.0 action SetScreenVariable("flag_var", True) repeat False

    else: # show some buttons
        vbox:
            textbutton "Test!" action NullAction()

https://www.renpy.org/doc/html/screens.html#timer
https://www.renpy.org/doc/html/screen_a ... enVariable

Thank you all. So far I've only tried Alex's approach, and it works great with one exception. The close button does not delay. Originally the close button had its own screen, but to try to make it delay with the other buttons I added it to the same screen. I'm including some screenshots and a larger section of code so I hopefully don't miss what's making this happen.

...

Edit: I forgot about the hud screen(s) I had made to call in these screens after adding open world gameplay. Removed the line to call close hud screen and that fixed it.

[RVNSN]

While you could use a timer I don't recommend that as it seems timer's are quite intensive.

Why not split the two? either have it on two screens, so on one screen you have the animation and then the other has buttons and you call it like:
show screen animation
pause 5#duration of animation
hide screen animation #this is so that if a player clicks he can skip the animation
call screen mainthingy

Or you can even avoid the screen for the animation and simply use an image but the same method as above:
show ships_log_opening_anim_1
pause 5
hide ships_log_opening_anim_1
call screen mainthingy

nananame, what would the code be like for that?

[nananame]

Exactly what I wrote?

So, if you want to have it on two screens then when a button is clicked to open the stats screen you go to label open_stat_screen:

Code: Select all

label open_stat_screen:
	show screen animation
	pause 5#duration of animation
	hide screen animation
	call screen statpage

Code: Select all

screen animation():
	add "ships_log_opening_anim_1"

Code: Select all

screen statpage():
    fixed:
        imagebutton auto "gui/clear_overlay_%s.png":
            xalign 0.5
            yalign 0.5
            action NullAction()

    vbox:
        textbutton "[name]":
            text_color "#000000"
            text_hover_color "#980002"
            xpos 550 ypos 150
            action ui.callsinnewcontext ("call_panstat")

So what happens here? Basically when you want to open the stat screen you go to the label. The label first shows the screen which has nothing but the animation and pauses for the duration of the animation. Once the animation is done (or the player clicks to interrupt it - you can put a hard pause too, but I suggest letting players skip it) the screen with the animation is hidden and the stat screen is called. This works fine but there's no real reason to have one screen just for the animation. So you can do the animation without a screen:

Code: Select all

label open_stat_screen:
	show ships_log_opening_anim_1 ###this is the animation you define with atl
	pause 5
	hide ships_log_opening_anim_1
	call screen statpage

[RVNSN]

Exactly what I wrote?

So, if you want to have it on two screens then when a button is clicked to open the stats screen you go to label open_stat_screen:

right on, thank you. i was trying to figure out how the parts that go under label worked in a screen.

[RVNSN]

Exactly what I wrote?

So, if you want to have it on two screens then when a button is clicked to open the stats screen you go to label open_stat_screen:

If I use jump to label in the stats screen the navigation screens (maybe even dialogue box) disappear and I end stuck on that screen without being able to do anything when I close the book.

And is there a way to include Alex's solution as one of the actions for a button? I'm trying to show one animation when flipping forward and another flipping backward upon return without having to duplicate the screens involved.