Character Moving Forward while Talking

[GoingGoingKeith]

Hi everyone! I'm trying to do something similar to DokiDoki Literature where the character moves forward as they talk. I know it has something to do with character callbacks, but I've never worked with them before. There is a thread out there with some code, I tested it but it dosen't seem to be working. Any inisight into this solution would be appreciated. Thanks! Aviewtopic.php?t=50142

[Angelo Seraphim]

Hi @GoingGoingKeith,

Here's what I use in my game:

Code: Select all

init python:
    def stacey_callback(event, interact=True, **kwargs):
        if not interact:
            return
	
	## Voice bleeps
        if event == "show_done":
            renpy.sound.play("audio/voice/stacey_bip.wav",
                             channel='voice_bleeps', fadein=0.1)
        elif event == "slow_done":
            renpy.sound.stop(channel='voice_bleeps', fadeout=0.1)
	
	## If the character is currently shown on screen, this will search for the character 'tag'
        if renpy.showing("anastasia"):
        
            if event == 'begin': ## When the character is speaking.
                renpy.show("anastasia", zorder=10, at_list=[speaking])
                
            elif event == 'end': ## When the character is not the current speaking character.
                renpy.show("anastasia", zorder=0, at_list=[not_speaking])
                
define an = Character('Stacey', image="anastasia", callback=stacey_callback)

The transform:

Code: Select all

transform speaking:
    subpixel True transform_anchor True yanchor 0.0
    ease 0.15 yoffset 30 zoom 1.0

    on hide:
        alpha 1.0
        linear 0.5 alpha 0.0

transform not_speaking:
    subpixel True transform_anchor True yanchor 0.0
    ease 0.15 yoffset 30 zoom 0.85

    on hide:
        alpha 1.0
        linear 0.5 alpha 0.0

Note: The transform may not work correctly for you, however, it should zoom the character in when speaking and out when they're currently not the speaking character.

[GoingGoingKeith]

Thank you! That worked nicely! I needed to put the character definition after the function though. My code ended up looking like this:

Code: Select all

transform speaking:
    linear 0.2 zoom 1.05
transform not_speaking:
    linear 0.2 zoom 1.0
init python:
    def stacey_callback(event, interact=True, **kwargs): ##Can change the function name later on.
        if not interact: 
            return
            ## If the character is currently shown on screen, this will search for the character 'tag'
        if renpy.showing("daisuke"):
        
            if event == 'begin': 
                renpy.show("daisuke", zorder=10, at_list=[speaking])
                
            elif event == 'end': 
                renpy.show("daisuke", zorder=0, at_list=[not_speaking])
define d = Character("Daisuke", image = "daisuke", callback=stacey_callback)