Chinese keeps using squares only[SOLVED]

[rebellare]

So, all the documentation I went through resulted in nothing. I tried everything I could think of and the only thing I noticed is that the game name (when the game is turned on) is actually in chinese, everything else is just squares, no matter what I do. I already got russian working long time ago and it did the same thing at first, but I got it working, can't even remember how anymore. The current solution that's out there is "copy east_asian.rpy from /extras", but the extras directory doesn't exist anymore so I can't get the east_asian.rpy file. I'm completely lost now and it's starting to drive me mad. Please help!

I got a menu that lets you choose a language and the chinese choice is:

Code: Select all

imagebutton auto "buttons/lang_choice_chi_%s.png" focus_mask True action [Language("chinese"), Function(font_change), Return(None)]

and the font_change function does this:

Code: Select all

if _preferences.language == u"chinese":
            gui.text_font = "Muyao-Softbrush-2"
            gui.name_text_font = "Muyao-Softbrush-2"
            gui.interface_text_font = "Muyao-Softbrush-2"
            gui.button_text_font = gui.interface_text_font
            gui.choice_button_text_font = gui.text_font
            gui.text_size = 15
            gui.name_text_size = 20
            gui.interface_text_size = 10
            gui.label_text_size = 15
            gui.notify_text_size = 10
            gui.title_text_size = 30
            gui.button_text_size = gui.interface_text_size
            gui.quick_button_text_size = 10
            gui.choice_button_text_size = gui.text_size
            gui.slot_button_text_size = 10

[Ocelot]

Changing gui variables in-game does nothing to already existing styles. YOu need to rebuild them.

Also, I believe, such style changes are expected to be done through style translations, since style and gui objects are not saved, and simple reloading can break the game.

[Imperf3kt]

I also wonder,

Code: Select all

gui.text_font = "Muyao-Softbrush-2"

Shouldn't this include the file extension?

Code: Select all

gui.text_font = "Muyao-Softbrush-2.ttf"

[PyTom]

You can do:

Code: Select all

translate chinese python:
            gui.text_font = "Muyao-Softbrush-2.ttf"
            gui.name_text_font = "Muyao-Softbrush-2.ttf"
            gui.interface_text_font = "Muyao-Softbrush-2.ttf"
            gui.button_text_font = gui.interface_text_font
            gui.choice_button_text_font = gui.text_font
            gui.text_size = 15
            gui.name_text_size = 20
            gui.interface_text_size = 10
            gui.label_text_size = 15
            gui.notify_text_size = 10
            gui.title_text_size = 30
            gui.button_text_size = gui.interface_text_size
            gui.quick_button_text_size = 10
            gui.choice_button_text_size = gui.text_size
            gui.slot_button_text_size = 10
[code]

Note that you do need to stick the font in game/ , as Ren'Py no longer looks at system fonts.

[rebellare]

Thanks for the reply, I've been dabbling since then and already realized that the changes I did changed nothing since they were local so I changed everything to define. Naturally, since they're "define" it just went through everything despite the conditions I set and just did the defines that were furthest below -.-
Currently there are english, spanish, russian, german and chinese and the chinese/russian are giving me the most trouble since it's different characters. I have a font that works for one and a font that works for the other. I made a screen that the players receive upon opening the game and they can re-open it while in main menu:

Code: Select all

screen choose_lang_main:
    zorder 0
    tag menu

    image "bg/lang_choice_bg.jpg"

    vbox:
        imagebutton auto "buttons/lang_choice_eng_%s.png" focus_mask True action [Language(None), Jump("after_lang_choice")]

    vbox:
        imagebutton auto "buttons/lang_choice_ger_%s.png" focus_mask True action [Language(None), Jump("after_lang_choice")]

    vbox:
        imagebutton auto "buttons/lang_choice_spa_%s.png" focus_mask True action [Language("spanish"), Jump("after_lang_choice")]

    vbox:
        imagebutton auto "buttons/lang_choice_rus_%s.png" focus_mask True action [Language("russian"), Jump("after_lang_choice")]

    vbox:
        imagebutton auto "buttons/lang_choice_chi_%s.png" focus_mask True action [Language("chinese"), Jump("after_lang_choice")]

and then I had set up a label to change the fonts and whatever else I needed/wanted, like text size (at least, that's what I planned...)

Code: Select all

label after_lang_choice:
    if preferences.language == "russian":
        $ gui.text_font = "DejaVuSans.ttf"
        $ gui.name_text_font = "DejaVuSans-Bold.ttf"
        $ gui.interface_text_font = "DejaVuSans-Bold.ttf"
        $ gui.button_text_font = gui.interface_text_font
        $ gui.choice_button_text_font = gui.text_font
        #-10
        $ gui.text_size = 23
        $ gui.name_text_size = 30
        $ gui.interface_text_size = 18
        $ gui.label_text_size = 21
        $ gui.notify_text_size = 15
        $ gui.title_text_size = 60
        $ gui.button_text_size = gui.interface_text_size
        $ gui.quick_button_text_size = 16
        $ gui.choice_button_text_size = gui.text_size
        $ gui.slot_button_text_size = 16

    elif preferences.language == "chinese":
        $ gui.text_font = "Muyao-Softbrush-2.ttf"
        $ gui.name_text_font = "Muyao-Softbrush-2.ttf"
        $ gui.interface_text_font = "Muyao-Softbrush-2.ttf"
        $ gui.button_text_font = gui.interface_text_font
        $ gui.choice_button_text_font = gui.text_font
        $ gui.text_size = 28
        $ gui.name_text_size = 35
        $ gui.interface_text_size = 23
        $ gui.label_text_size = 26
        $ gui.notify_text_size = 20
        $ gui.title_text_size = 65
        $ gui.button_text_size = gui.interface_text_size
        $ gui.quick_button_text_size = 21
        $ gui.choice_button_text_size = gui.text_size
        $ gui.slot_button_text_size = 21

    else:#english/spanish/german
        $ gui.text_font = "DejaVuSans.ttf"
        $ gui.name_text_font = "DejaVuSans-Bold.ttf"
        $ gui.interface_text_font = "DejaVuSans-Oblique.ttf"
        $ gui.button_text_font = gui.interface_text_font
        $ gui.choice_button_text_font = gui.text_font
        #-10
        $ gui.text_size = 28
        $ gui.name_text_size = 35
        $ gui.interface_text_size = 23
        $ gui.label_text_size = 26
        $ gui.notify_text_size = 20
        $ gui.title_text_size = 65
        $ gui.button_text_size = gui.interface_text_size
        $ gui.quick_button_text_size = 21
        $ gui.choice_button_text_size = gui.text_size
        $ gui.slot_button_text_size = 21

    return

This is pretty much where I'm at now. If only I could somehow change these variables and have them STAY after leaving the main menu, I'd be golden.
I hope this shows what I'm stuck at currently in more detail. Also, I did put all the languages into the /game folder and they all work, separately, but not when I try giving the players a choice. I would like it to remain as a "main menu only" choice so the lack of knowledge to make the changes stay "changed" is killing me.

[rebellare]

Of course, if there is a smarter, simpler option to do what I'm trying to, I'd be really grateful

[PyTom]

I'm a bit confused by what you're doing here. You seem to be trying to implement your own translation system, that's not the one that's implemented in Ren'Py. By setting the translations in a translate python block, they'll be updated when the language changes, and when the game starts and restarts.

[rebellare]

Is this it?

Code: Select all

translate piglatin style default:
    font "stonecutter.ttf"
translate piglatin python:
    style.default.font = "stonecutter.ttf"

If yes, what's the difference? Since it says equivalently, I'm presuming it's either, right?

[rebellare]

Could you maybe show how it'd look for my project? just for one language, I'll do the rest, of course. What I want is the abilty to choose which font for dialgoue, names and interface and the sizes for them all

[Ocelot]

An example of how changing default font affects say screen:

Code: Select all

translate incomprehensible style default:
    font "CNTDN_.TTF"

translate fancy style default:
    font "Bolero script.ttf"

translate typewriter style default:
    font "B52.ttf"

screen lang_change():
    vbox:
        align (1.0, 0.0)
        label "What font do you want to use?"
        textbutton "normal" action Language(None)
        textbutton "fancy" text_font "Bolero script.ttf" action Language("fancy")
        textbutton "typewriter" text_font "B52.ttf" action Language("typewriter")
        textbutton "incomprehensible" text_font "CNTDN_.TTF" action Language("incomprehensible")


label start:
    show screen lang_change
    "Hello"
    "This is test of font translation"
    "Enjoy"
    return

In action: https://i.imgur.com/k16i74m.gif

Notice, that a lot of screen elements did not change. That is because they override default font somewhere in their styles. You will need to translate those too.

[rebellare]

So in my case, it'd be:

Code: Select all

translate chinese style default:
    font "ChineseFontThatIFound.ttf"

and what would I use to change to font of names and my interface?
I mean, the equivalents of "gui.name_text_font" and "gui.interface_text_font" since font is equivalent to gui.text_font, I'm presuming

[Ocelot]

1) Check the styles those entries use. Either checking corresponding screens, or pressing Shift+I while hovering above text you want to inspect to open Style Inspector:

Pressing Shift+I here to find out label style:

Guess it is label_text...

But actually, font is overriden earlier by gui_text!

I can just replace that instead!

2) Translate styles you need. You probably want styles gui_text and button_text. Those should account to almost 100% of fonts used in default gui.

[rebellare]

Great! Thanks a lot! I'll try making it work today, fingers crossed

[rebellare]

Made it work with styles, gonna put the subject as resolved. Thanks a lot, everyone!