Is there a way to force a redraw of the dialogue window?

[AVNSnax]

Is there a way to force a redraw of the dialogue window? Long story short, I'm disabling CTC display if the user is in auto-forward mode. When I turn Auto on, it's not a problem because afm will force subsequent screens to appear after a delay. But turning Auto off (and turning the CTC back on) there is no CTC visual cue to remind the user to, uh, click to continue to the next screen until the dialogue refreshes by, um, clicking to continue.

I thought it might be as simple as

Code: Select all

renpy.redraw(renpy.get_screen("say"), 0)

but nothing happens--I assume Ren'Py knows that the screen doesn't have to be redrawn because nothing has changed. Thanks.

[m_from_space]

You could try:

Code: Select all

renpy.restart_interaction()

[AVNSnax]

You could try:

Code: Select all

renpy.restart_interaction()

That's the first thing I tried. Nothing happens. Does it matter where it's called from? Right now, it's an action from the quick menu:

Code: Select all

    def setupCTC():
        ctcBehavior = None if preferences.afm_enable else renpy.easy.displayable_or_none("ctc_blink")
        for c in allCharacters:
            c.display_args['ctc'] = ctcBehavior
        renpy.restart_interaction()
    . . .
                if _preferences.afm_enable:
                    imagebutton:
                        activate_sound "audio/se_click.mp3"
                        idle "gui/button/auto_hover.png"
                        hover "gui/button/auto_idle.png"
                        action [Preference("auto-forward", "toggle"), Function(setupCTC)]
                        tooltip "Auto disable"
                else:
                    imagebutton:
                        activate_sound "audio/se_click.mp3"
                        idle "gui/button/auto_idle.png"
                        hover "gui/button/auto_hover.png"
                        action [Preference("auto-forward", "toggle"), Function(setupCTC)]
                        tooltip "Auto enable"

[AVNSnax]

I continue to try to solve this problem. Some people have tried to convince me that this is a "non-issue," but it frustrates me that there isn't a way to do something so common in a video game as redrawing parts of the screen.

[Alex]

...

Try DynamicDisplayable - https://www.renpy.org/doc/html/displaya ... isplayable

Something like

Code: Select all

init python:
    def ctc_return(st, at, ctc):
        if my_var:
            return ctc, 0.1
        return Null(), 0.1
        
define e = Character("Eileen", who_color="#909", ctc=DynamicDisplayable(ctc_return, ctc=Text("A") ) )

        
default my_var = True

# The game starts here.

label start:
    $ my_var = True
    e "..."
    $ my_var = False
    e "... ..."
    $ my_var = True
    e "?!"

[AVNSnax]

...

That was simpler than my brute force method, so thanks! My issue with screen updates remains:

• If auto-forward is off and enabled, the screen automatically shows the following screen with CTC now disabled. No problem.

• If auto-forward is on and disabled, the screen displays no CTC icon until the user clicks to the next screen. Issue.

That's why I asked about forcing a redraw of the dialogue window. I could see several instances where such a feature might come in handy. Given the relatively low overhead, I don't think there would need to have a fancy system for buffering requests to redraw, especially with as often as the say screen is called.

Any other suggestions are welcome!

[Imperf3kt]

Why not just use the default CTC screen and add a single condition check to the CTC screen? If in afm, the screen won't show, if not, it shows.

Does this not work as expected?

[AVNSnax]

Why not just use the default CTC screen and add a single condition check to the CTC screen? If in afm, the screen won't show, if not, it shows.
Does this not work as expected?

I'm using a nestled-close icon in-line with the text. There is no separate CTC screen.

[Alex]

...

• If auto-forward is on and disabled, the screen displays no CTC icon until the user clicks to the next screen. Issue.

...

This seems to work for me

Code: Select all

image blue:
    Solid("#00c")
    size(100, 100)

init python:
    def ctc_return(st, at, ctc):
        # if player not skipping text and
        # game not in auto-forward mode
        if not renpy.get_skipping() and not preferences.afm_enable:
            return ctc, 0.1
        return Null(), 0.1

transform test_ctc_anim(t=1.0):
    alpha 0.0
    linear t/2.0 alpha 1.0
    linear t/2.0 alpha 0.0
    repeat
        
image test_ctc:
    "blue"
        
define e = Character("Eileen", who_color="#909", ctc_position="nestled-close", ctc=DynamicDisplayable(ctc_return, ctc=At('test_ctc', test_ctc_anim) ) )


# The game starts here.

label start:
    $ i = 0
    while i < 500:
        $ i += 1
        e "... [i] ...\nText text text some more text..."
    "?!"

https://www.renpy.org/doc/html/other.ht ... t_skipping
https://www.renpy.org/doc/html/preferen ... afm_enable
https://www.renpy.org/doc/html/displayables.html#At

[AVNSnax]

This seems to work for me

Hmm. The only difference in our code (besides my using an image without applying a transform) was your direct reference to the image, which my code couldn't find which is why I added the calls in the first place to renpy.easy.displayable_or_none() to retrieve the displayable from the name. I moved the image declaration into the file and it all started working. Must have been a scoping error.

Thanks Alex! I really appreciate it!